Remove "OpenReport action cancelled" message from button code

[templeowls]

I have a button in a form which opens up a report. The report is controlled by a query that has criteria search fields. If a user presses the button and is prompted with a criteria search box but cancels out of it, access shows the message "The OpenReport action was canceled"



Is there any way to get rid of this message from appearing? Exiting out of the criteria search box is common and this message is just one extra click. The code for the button is below. Thanks!

Private Sub btnOpenReport_Click()On Error GoTo btnOpenReport_Click_Err


    DoCmd.OpenReport "rptComplaints", acViewReport, "", "", acNormal


btnOpenReport_Click_Exit:
    Exit Sub


btnOpenReport_Click_Err:
    MsgBox Error$
    Resume btnOpenReport_Click_Exit


End Sub

[Bob Fitz]

Perhaps you could replace: MsgBox Error$ with MsgBox Err.Number which will tell you the error number.
Once you know the number you could handle the error with code If/Then using Resume btnOpenReport_Click_Exit when you've caught it with If/Then

[davegri]

To expand on Bob's suggestion,
See if this will handle it:

Private Sub btnOpenReport_Click()
    On Error GoTo Error_Handler
    DoCmd.OpenReport "rptComplaints", acViewReport, "", "", acNormal
Error_Handler_Exit:
    On Error Resume Next
    Exit Sub
Error_Handler:
    Select Case Err
        Case 2501   'ignore, user cancelled
        Case Else
            MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure btnOpenReport_Click" & "."
    End Select
    Resume Error_Handler_Exit
End Sub

[templeowls]

To expand on Bob's suggestion,
See if this will handle it:

Private Sub btnOpenReport_Click()
    On Error GoTo Error_Handler
    DoCmd.OpenReport "rptComplaints", acViewReport, "", "", acNormal
Error_Handler_Exit:
    On Error Resume Next
    Exit Sub
Error_Handler:
    Select Case Err
        Case 2501   'ignore, user cancelled
        Case Else
            MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure btnOpenReport_Click" & "."
    End Select
    Resume Error_Handler_Exit
End Sub

That worked!! Thank you both