send password in Ms access to email

[Mehvan]

Hello everyone



I have a question about sending password from Ms Access to Email (Yahoo)
I have a project in Ms Access , many users using it , and of course everyone will has special ( Name and Password )
I would like to create one form , if someone forget his/her password , He will tell manager about password
manager will go to that form and will enter his email Yahoo , will send password to his Email yahoo

Am I can do it in Microsoft Access , because Yahoo should has network even We can work on Yahoo , and Microsoft Access doesn't work with network now , I mean my Ms Access project .

[ranman256]

you can skip this by just using Window Login authentication.
Their windows login/password is the same used for the access db.
Keep the userID table as the list of users allowed to be in the db, but no need to keep passwords.

SUB btnLogin_Click()
Dim sUser As String, sPass As String, sDom As String

sUser = txtUser
sPass = txtPass
sDom = "CoDomain"

if sUser = Dlookup("userid","tUsers","[userid]='" & sUser & "'") then
If WindowsLogin(sUser, sPass, sDom) Then
   mbSafe = True
   DoCmd.OpenForm "frmMainMenu"
   DoCmd.OpenForm "frmLogin"
   DoCmd.Close
Else
   MsgBox "LOGIN INCORRECT", vbCritical, "Bad userid or password"
End If
end if
end sub

'-----------------
Public Function WindowsLogin(ByVal strUserName As String, ByVal strpassword As String, ByVal strDomain As String) As Boolean
'-----------------

        'Authenticates user and password entered with Active Directory.

        On Error GoTo IncorrectPassword
        
        Dim oADsObject, oADsNamespace As Object
        Dim strADsPath As String
        
        strADsPath = "WinNT://" & strDomain
        Set oADsObject = GetObject(strADsPath)
        Set oADsNamespace = GetObject("WinNT:")
        Set oADsObject = oADsNamespace.OpenDSObject(strADsPath, strDomain & "\" & strUserName, strpassword, 0)
        
        WindowsLogin = True    'ACCESS GRANTED
        
ExitSub:
        Exit Function
        
IncorrectPassword:
        WindowsLogin = False   'ACCESS DENIED
        Resume ExitSub
End Function

[Mehvan]

thanks a lot ,,, I will try to apply it