AutoExec File to Set a Timer and Limit Access

[Jays35]

First of all new to the forum and sort of a newbie to MS Access!



We have several users of MS Access and would like to give users limited access (read only) and if there is no movement (mouse), a would timer shuts their session off. What would be a good way to do this action to shut their session off? Maybe it would save their session before shutting down. We are on a Network and each of us have a delivered Icon to start the Access.

Thanks in advance

Dave

[aytee111]

This code is attached to a form with its Timer Interval set to 1000 and this event called in the OnTimer event. It definitely will not close the session. The code will display a message to the user, you can change that to close the database or whatever you want to happen.

 
Sub Form_Timer()
' https://support.microsoft.com/en-us/kb/128814
' IDLEMINUTES determines how much idle time to wait for before
' running the IdleTimeDetected subroutine.
Const IDLEMINUTES = 60
Static PrevControlName As String
Static PrevFormName As String
Static ExpiredTime
Dim ActiveFormName As String
Dim ActiveControlName As String
Dim ExpiredMinutes
On Error Resume Next
' Get the active form and control name.
ActiveFormName = Screen.ActiveForm.Name
If Err Then
   ActiveFormName = "No Active Form"
   Err = 0
End If
ActiveControlName = Screen.ActiveControl.Name
   If Err Then
   ActiveControlName = "No Active Control"
   Err = 0
End If
' Record the current active names and reset ExpiredTime if:
'    1. They have not been recorded yet (code is running
'       for the first time).
'    2. The previous names are different than the current ones
'       (the user has done something different during the timer
'        interval).
If (PrevControlName = "") Or (PrevFormName = "") Or (ActiveFormName <> PrevFormName) Or (ActiveControlName <> PrevControlName) Then
   PrevControlName = ActiveControlName
   PrevFormName = ActiveFormName
   ExpiredTime = 0
Else
   ' ...otherwise the user was idle during the time interval, so
   ' increment the total expired time.
   ExpiredTime = ExpiredTime + Me.TimerInterval
End If
'Debug.Print IDLEMINUTES
'Debug.Print ExpiredTime
' Does the total expired time exceed the IDLEMINUTES?
ExpiredMinutes = (ExpiredTime / 1000) / 60
'Debug.Print ExpiredMinutes
If ExpiredMinutes >= IDLEMINUTES Then
   ' ...if so, then reset the expired time to zero...
   ExpiredTime = 0
   ' ...and call the IdleTimeDetected subroutine.
   IdleTimeDetected ExpiredMinutes
End If
End Sub

Sub IdleTimeDetected(ExpiredMinutes)
    Dim Msg As String
    Msg = "No user activity detected in the last "
    Msg = Msg & ExpiredMinutes & " minute(s)!"
    MsgBox Msg, 48
 End Sub

[Jays35]

Thanks for the info!

[ssanfu]

We are on a Network and each of us have a delivered Icon to start the Access.

I hope your dB is split!