Information text on unbound text box

[randle]

Hi,



I want to do the same as what can be found here https://www.accessforums.net/forms/t...ars-34365.html however, I'd like the unbound text box to show this informational text all the time unless it has taken focus.

I'd also like to be able to format this text ie. font type, size, style etc. which I imaging can again be specified through the code!?

One other thing I've noticed is that when clicking in the text box the informational text doesn't disappear and instead lets you add to this text at the position of the cursor. In the ideal world I simply want it to disappear when focus is gained so that when you start typing, this is the only text that's shown.

[Missinglinq]

I think this meets your requirement, but note that it can only be used on a Single View Form, not on a Datasheet or Continuous View Form. It uses a super-imposed Label, for the display text, and can be formatted by simply selecting the Label and using the Formatting Tab on the Ribbon/Menu

• Delete the Textbox’s attached Label
• Create new Label for Textbox with the Caption of choice
• Set BackStyle and BorderStyle of the Label to Transparent
• Position Label inside of the Textbox
  

Now, use this code, replacing TargetFieldLabel and TargetField with the actual names of your Controls:

Private Sub Form_Current()

If Nz(Me.TargetField, "") <> "" Then
  TargetFieldLabel.Visible = False
Else
  TargetFieldLabel.Visible = True
End If

End Sub

Private Sub TargetField_GotFocus()
 
  TargetFieldLabel.Visible = False

End Sub

Private Sub TargetFieldLabel_Click()

  TargetField.SetFocus

End Sub

Private Sub TargetField_LostFocus()

If Nz(Me.TargetField, "") <> "" Then
  TargetFieldLabel.Visible = False
Else
  TargetFieldLabel.Visible = True
End If

End Sub

Linq ;0)>

[randle]

What a legend. Thanks so much. Works a treat...and first time!!

[Missinglinq]

Glad we could help!

Linq ;0)>