And or statement help

[dhicks19]

Hi, please can you have a look at my code, I have this on a button on a form that has an ID number and two check boxed humidity and temp.


My issue is that its triggering them all instead of just one and im getting multiple forms open.
Im new to access and I dont know where I am going wrong,please help.


Option Compare Database
Option Explicit

Private Sub Command2_Click()



With DoCmd
If Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162" And Me.Humidity = True And Me.Temp = False Then

.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecaldata2"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresultsmulti"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("TRUE FALSE ID")


End If

If Me.ID <> "160" Or Me.ID <> "161" Or Me.ID <> "162" And Me.Humidity = True And Me.Temp = False Then

.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecaldata2"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresults2"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("TRUE FALSE NOT ID")



End If



If Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162" And Me.Humidity = True And Me.Temp = True Then

.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecaldata2"
.OpenQuery "qrymakecaldatatemp"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresultsmulti"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("TRUE TRUE ID")

End If

If Me.ID <> "160" Or Me.ID <> "161" Or Me.ID <> "162" And Me.Humidity = True And Me.Temp = True Then



.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecaldata2"
.OpenQuery "qrymakecaldatatemp"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresults2"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("TRUE TRUE NOT ID")


End If


If Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162" And Me.Temp = True And Me.Humidity = False Then


.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecaldatatemp"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresultsmulti"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("TRUE FALSE ID")


End If


If Me.ID <> "160" Or Me.ID <> "161" Or Me.ID <> "162" And Me.Temp = True And Me.Humidity = False Then

.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecaldatatemp"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresults2"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("TRUE FALSE NOT ID")


End If





If Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162" And Me.Humidity = False And Me.Temp = False Then


.SetWarnings False
.OpenQuery "qrymakecaldata"
.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresultsmulti"
.SelectObject acForm, "frmmakecaldata"
.Minimize
MsgBox ("FALSE ID")

End If




If Me.ID <> "160" Or Me.ID <> "161" Or Me.ID <> "162" And Me.Humidity = False And Me.Temp = False Then

.SetWarnings False
.OpenQuery "qrymakecaldata"
'.OpenQuery "qrymakecalref"
.SetWarnings True
.OpenForm "frmcalresults"
.SelectObject acForm, "frmmakecaldata"
MsgBox ("FALSE NOT ID")
.Minimize
End If
End With


End Sub

[ssanfu]

The IF() statement need modified. The three Me.IDs need to be enclosed in parenthesis:

If (Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162") And Me.Humidity = True And Me.Temp = False Then

Do this for all of the IF()'s.

This could probably be condensed by a rewrite since there are conditions that are similar.... If you want, I'll look at it tonight.

[John_G]

Hi -

In addition to what ssanfu has pointed out, this:

Me.ID <> "160" Or Me.ID <> "161" Or Me.ID <> "162" will ALWAYS be true, regardless of the value of Me.ID - if Me.ID is equal to one of those three values, then obviously it is not equal to the other two!

If you want the condition to be true when Me.ID is not equal to any of those values, you can use

(Me.ID <> "160" And Me.ID <> "161" And Me.ID <> "162" )
or
Not (Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162" )

In this case, I think the latter one is clearer.

HTH

John

[ssanfu]

This is how I would structure the code:

Private Sub Command2_Click()
   With DoCmd
      If (Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162") Then
         If Me.Humidity = True Then
            If Me.Temp = True Then
               '   I prefer to use the Execute Method
               '               CurrentDb.Execute "qrymakecaldata", dbFailOnError
               '               CurrentDb.Execute "qrymakecaldata2", dbFailOnError
               '               CurrentDb.Execute "qrymakecaldatatemp", dbFailOnError

               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecaldata2"
               .OpenQuery "qrymakecaldatatemp"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True

               .OpenForm "frmcalresultsmulti"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("TRUE TRUE ID")
            Else
               '     Me.Temp = False
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecaldata2"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresultsmulti"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("TRUE FALSE ID")
            End If   'Me.Temp
         Else
            '     If Me.Humidity = False
            If Me.Temp = True Then
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecaldatatemp"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresultsmulti"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("FALSE TRUE ID")
            Else
               '     Me.Temp = False
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresultsmulti"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("FALSE FALSE ID")
            End If  'Me.Temp
         End If  'Me.Humidity
      Else
         '         Not (Me.ID = "160" Or Me.ID = "161" Or Me.ID = "162")
         If Me.Humidity = True Then
            If Me.Temp = True Then
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecaldata2"
               .OpenQuery "qrymakecaldatatemp"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresults2"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("TRUE TRUE NOT ID")
            Else
               '     Me.Temp = False
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecaldata2"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresults2"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("TRUE FALSE NOT ID")
            End If  ' Me.Temp
         Else
            '     Me.Humidity = False
            If Me.Temp = True Then
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               .OpenQuery "qrymakecaldatatemp"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresults2"
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("FALSE TRUE NOT ID")
            Else
               '     Me.Temp = False
               .SetWarnings False
               .OpenQuery "qrymakecaldata"
               '.OpenQuery "qrymakecalref"
               .SetWarnings True
               .OpenForm "frmcalresults"   '<< shouldn't this be "frmcalresults2"   ???
               .SelectObject acForm, "frmmakecaldata"
               .Minimize
               MsgBox ("FALSE FALSE NOT ID")
            End If  'Me.Temp
         End If   'Me.Humidity
      End If   'Me.ID
   End With  'Docmd

End Sub

There is more that can be done to reduce duplication of commands. For example, these two lines are in every IF() block (8 places = 16 lines):

.SelectObject acForm, "frmmakecaldata"
.Minimize

They could all be deleted from the IF() blocks and moved to just above the "END SUB" line (1 place = 2 lines).

Just my $0.02

[dhicks19]

thank you for your help