Any idea to get this VBA code more efficient?

[HansH]

Dear all,

I'm trying to get a range of Togglebuttons to be enabled and fire a filter. Is there a way more efficient than this? any idea is appreciated since the coding page gets very long in this way.

Thank in advance.

Hans.

Private Sub Toggle282_AfterUpdate()
If Me.Tekst302 = 0 Then
Me.Toggle282 = False
Else
If Me.Toggle282 = True Then
DoCmd.GoToControl "query1"
DoCmd.SetFilter "", "[profiel type]=""vac""", ""
Me.Toggle25.Enabled = False


Me.Toggle23.Enabled = False
Me.Toggle37.Enabled = False
Me.Toggle31.Enabled = False
Me.Toggle44.Enabled = False
Me.Toggle41.Enabled = False
Me.Toggle47.Enabled = False
Else
DoCmd.GoToControl "query1"
DoCmd.RunCommand acCmdRemoveFilterSort
Me.Toggle25.Enabled = True
Me.Toggle23.Enabled = True
Me.Toggle37.Enabled = True
Me.Toggle31.Enabled = True
Me.Toggle44.Enabled = True
Me.Toggle41.Enabled = True
Me.Toggle47.Enabled = True
End If
End If
End Sub

[moke123]

Use the tag property of the controls. You then iterate through the forms control collection and either set it enabled or dis-abled.

Something along the lines of:

For each ctl in me.controls

if ctl.tag = "XYZ" then

ctl.enabled = true

else

ctl.enabled = False

end if

[Welshgasman]

For a start, please post code within code tags. That keeps the indentation which I hope you are using?

Try

Private Sub Toggle282_AfterUpdate()
    If Me.Tekst302 = 0 Then
        Me.Toggle282 = False
    Else
        DoCmd.GoToControl "query1"
        Me.Toggle25.Enabled = Not Me.Toggle282
        Me.Toggle23.Enabled = Not Me.Toggle282
        Me.Toggle37.Enabled = Not Me.Toggle282
        Me.Toggle31.Enabled = Not Me.Toggle282
        Me.Toggle44.Enabled = Not Me.Toggle282
        Me.Toggle41.Enabled = Not Me.Toggle282
        Me.Toggle47.Enabled = Not Me.Toggle282
        
        If Me.Toggle282 = True Then
            DoCmd.SetFilter "", "[profiel type]=""vac""", ""
        Else
            DoCmd.RunCommand acCmdRemoveFilterSort
        End If
    End If
End Sub

[moke123]

A generic sub to handle the toggles

Public Sub SetControls(frm As Form, TorF As Boolean, MyTag As String)

    Dim ctl As Control

For Each ctl In frm.Controls
    
        If ctl.Tag = MyTag Then

            ctl.Enabled = TorF

        End If

    Next

End Sub

You would call it like

SetControls Me, True, "XYZ"

or

SetControls Me, False, "XYZ"

[isladogs]

I use very similar code which you can find in my example app Set Controls (isladogs.co.uk)

[June7]

Loop through all controls on form or limit loop to the toggles. Assign names with sequential number suffix: Toggle1, Toggle2, etc.

For x = 1 to 7
    Me("Toggle" & x).Enabled = Not Me.Toggle282
End If