How to .SetFocus after a timer event?

[JB510]

I have a form and if the user enters the wrong info in the txtbox, I have it flashing a message in a label for 2 seconds.
The problem is how can I get it go go back to the txtbox after the timer event. (I've tried the SetFocus command inside and outside the Private Sub and it still don't set the focus back.)

Private Sub Form_Timer()
LblError.Caption = "Wrong Value"
Me!LblError.Visible = Not Me!LblError.Visible
txtbox = ""


txtbox.SetFocus
End Sub

Help-Please?

[J-Man]

Would you use something like DoCmd.GoToControl "txtBox"

[Micron]

Using a timer like that is a bad idea IMO, because you'd have to alter the timer property after it runs, otherwise it just continues to run? I'd probably use BeforeUpdate event and a pause function. Then when control returns from the pause function, set the focus, but...

I would not directly refer to controls on a form as in txtBox but rather Me.txtBox, nor would I use Me! instead of Me. Not sure if that has anything to do with your focus problem since I'd never write it that way. Probably not related. txtBox is somewhat lacking as a control name, no?
Example of a pause function (5 seconds pause called as pause 5)

Sub pause(sngSecs As Single)
Dim endTime As Single

endTime = Timer
Do Until Timer > endTime + sngSecs
'Debug.Print Timer
Loop

End Sub

[Welshgasman]

Does it even clear the textbox?
I would use Me.txtbox ?

[JB510]

Still not working proper.. I tried this with the new timer code:

LblMB.Visible = True
LblMB.Caption = "Wrong Value"
pause 5
LblMB.Caption = ""
txtIIRNumber = ""
DoCmd.GoToControl "txtIIRNumber"
Exit Sub

It does not even update the LblMB with "Wrong Value". (It may flash it but I don't see it on screen.)
It also does not set the focus still.
txtIIRNumber does clear.
(With the Form timer on or off / Set to 5000 or 0)

It seems it does not update until the code is released/finished (including with pauses set which you have to wait for.)
The form only releases after the delay but the focus jumps to my exit button. (This button I tried moving in my tab order and around the screen and it still only releases it to it.)

[Minty]

Try a

Me.Repaint

after the caption settings to refresh any from changes.

[moke123]

try using the before update event.(as Micron suggested) If you cancel the update, focus remains in the textbox.

Private Sub Text0_BeforeUpdate(Cancel As Integer)
    Dim i As Integer


    If Me.Text0 <> "a" Then   'change for your criteria
        Cancel = True
    
        For i = 1 To 10
            If Me.LWarning.Visible = False Then
                Me.LWarning.Visible = True
            Else
                Me.LWarning.Visible = False
            End If
            Pause 0.25
        Next i

        Me.Text0.SelStart = 0
        Me.Text0.SelLength = Len(Me.Text0)

    End If

End Sub

Public Function Pause(NumberOfSeconds As Variant)

    On Error GoTo Err_Pause

    Dim PauseTime As Variant, start As Variant

    PauseTime = NumberOfSeconds
    start = Timer
    Do While Timer < start + PauseTime
        DoEvents
    Loop

Exit_Pause:
    Exit Function

Err_Pause:
    MsgBox Err.Number & " - " & Err.Description, vbCritical, "Pause()"
    Resume Exit_Pause

End Function

[JB510]

Thanks! I played with your code listed and got it to work! Thanks for your time, it was greatly appreciated!

[moke123]

We're all happy to help.

Good luck with your project.