If I understand correctly, you want to modify textbox label names on the form. All the data you need to do so is in the form. No need to look at tables. Copy this function code into a module and modify the literals in the Select Case to suit.
Feed the function the form names you want changed.
Code:
'---------------------------------------------------------------------------------------
' Method : fcnFormatAllLabels
' Author : davegri
' Date : 6/29/2021
' Purpose: Search form for textbox control source and change the textbox label value
'---------------------------------------------------------------------------------------
Public Function fcnFixFormLabels(frmName As String)
On Error GoTo Error_Handler
Dim ctl As Control, frm As Form
Dim CS As String, i As Integer, LN As String, counter As Long
DoCmd.Close acForm, frmName 'if it happens to be open
DoCmd.OpenForm frmName, acDesign
Set frm = Forms(frmName)
For Each ctl In frm.Controls 'could also be {For Each ctl In frm.Section(acDetail).Controls}
If ctl.ControlType = acTextBox Then
counter = counter + 1
LN = ctl.Controls(0).Caption 'this is the textbox's label value
CS = ctl.ControlSource 'this is the control source for the textbox
Debug.Print counter, LN, CS
Select Case CS
Case "DateMade"
ctl.Controls(0).Caption = "Creation Date"
Case "foo"
ctl.Controls(0).Caption = "foo you too"
Case Else
End Select
End If
Next ctl
DoCmd.Close acForm, frm.Name, acSaveYes
Error_Handler_Exit:
On Error Resume Next
Exit Function
Error_Handler:
Select Case Err
Case 2467 'ignore, textbox has no associated label
Resume Next
Case Else
MsgBox "Error " & Err.Number & " (" & Err.Description & ")", vbExclamation, "Error in Function fcnFixFormLabels of FWTuner"
End Select
Resume Error_Handler_Exit
Resume
End Function