Saving a file from a server

[UT227]

I'm trying to download a file from my server then let the user pick where to save it. I have already been able to have the user pick a file and upload it to where I want it to go. I thought it would just be the opposite. I'm having a hard time This is as far as I have gotten. But even this doesn't work the way I want it to. It is incomplete. I want it to just find the file and have the filedialog be there so the user can choose where he wants to save the file. I'm not sure if I'm even close.

Dim fDialog As filedialog

Set fDialog = Application.filedialog(msoFileDialogFilePicker)

With fDialog
.AllowMultiSelect = False
.Filters.Clear
.Filters.Add "Word File", "*.docx;*.doc"
.FilterIndex = 1


.InitialFileName = "\\ServerLocation\ServerFolder\Document.docx"
If .Show Then
'I haven't made it this far yet
End If
End With

[UT227]

Or if anyone has a link to instructions on how to this

[June7]

So now you want to allow user to select a folder.

Save the selected file to a variable.

If Not .Show Then
         MsgBox "You clicked Cancel in the file dialog box."
Else
strFile = .SelectedItems(1)
Dim sFolder As String
Dim fd As FileDialog
Dim booResult As Boolean
Set fd = Application.FileDialog(msoFileDialogFolderPicker)
fd.AllowMultiSelect = False
fd.title = "Select database folder"
fd.InitialFileName = "file:\\"
While booResult = False
    If fd.Show = True Then
        'folder path was selected
        booResult = True
        sFolder = fd.SelectedItems(1)
        Debug.Print sFolder 'here is where you could take the selected folder path and use it to save file using CopyFile or FileCopy
    End If
Wend
End If

I thought FileCopy is supposed to save a file to destination folder without specifying name to save as, using original file name. However, does not seem to be true. So will have to extract file name from the source file path and concatenate it to the selected folder path.

[UT227]

I messed up. Since I already know where the file is, I don't need to have the user select it. I had to start over again. So, I had to get the full path down like this:
Dim PathFolder As String
PathFolder = DLookup("FormsPath", "tblSystemDefaults") & "" & txtDocName

How would I use the file dialog to select where the user wants to save the file? Or is there a better way?

[June7]

I already show file dialog code for selecting destination folder.

[UT227]

I really thought I was understanding. I'm not so sure now. This is what I did. It brings up the file in the file dialog, but when you choose a destination, it chooses it in the name. Example is when I click on Desktop, the name of the file changed to Desktop.
Dim PathFolder As String
PathFolder = DLookup("FormsPath", "tblSystemDefaults") & ""

Dim sFolder As String
Dim fd As FileDialog
Dim booResult As Boolean
Set fd = Application.FileDialog(msoFileDialogFolderPicker)
fd.AllowMultiSelect = False
fd.Title = "Select folder"
fd.InitialFileName = PathFolder & Me.txtDocName
While booResult = False
If fd.Show = True Then
'folder path was selected
booResult = True
sFolder = fd.SelectedItems(1)
Debug.Print sFolder
FileCopy PathFolder & Me.txtDocName, sFolder
End If
Wend

[June7]

Does tblSystemDefaults have only one record? Does FormsPath value have ending \ character? If not, include it in the concatenation.

FileCopy PathFolder & "\" & Me.txtDocName, sFolder & "\" & Me.txtDocName



Please post lengthy code between CODE tags to retain indentation and readability. If you had a \ character between those quote marks, the forum dropped it because it saw it as part of a URL string. Go to Advanced editor and uncheck "Automatically parse links in text" every time you edit post so it won't drop \. Otherwise use CODE tags.

[UT227]

Yes, tblSystemDefaults has only one record. I found it easier that way. I did include it in the concatenation in PathFolder (PathFolder = DLookup("FormsPath", "tblSystemDefaults") & ""). It didn't come out when I did copy/paste.

[UT227]

How do I use code tags?

[June7]

On the post menu bar, click the # button. Paste your code between the tags. Or type the tags.

[UT227]

Here's the code:

    Dim PathFolder As String
    PathFolder = DLookup("FormsPath", "tblSystemDefaults") & "\"
    
    Dim sFolder As String
    Dim fd As FileDialog
    Dim booResult As Boolean
    Set fd = Application.FileDialog(msoFileDialogFolderPicker)
    fd.AllowMultiSelect = False
    fd.Title = "Select folder"
    fd.InitialFileName = PathFolder & Me.txtDocName
    While booResult = False
        If fd.Show = True Then
            'folder path was selected
            booResult = True
            sFolder = fd.SelectedItems(1)
        Debug.Print sFolder
        FileCopy PathFolder & Me.txtDocName, sFolder & "\" & Me.txtDocName
        End If
    Wend

[UT227]

It is working perfectly. Thanks.