This code that I wrote uses names from Excel sheet column A and dates from column B to create recurring Outlook calendar events. If no one provides more focused code it should get you started by at least revealing some of the calendar event properties. I realize it's for Excel - you would have to adapt. The AfterUpdate event (don't know which you need; for form or for control) would be the event to use to add a calendar event when you add a record. If you use code to create the initial events for your current records, you would not want to re-run the exact code each time you add a record. That would likely create duplicate events or at least errors.
Code:
Sub ImportBirthdaysToCalendar()
Dim objWorksheet As Excel.Worksheet
Dim nRow As Integer, nLastRow As Integer
Dim objOutlookApp As Outlook.Application
Dim objCalendar As Outlook.Folder
Dim objBirthdayEvent As Outlook.AppointmentItem
Dim objRecurrencePattern As Outlook.RecurrencePattern
'Get the specific sheet
Set objWorksheet = ThisWorkbook.Sheets(1)
nLastRow = objWorksheet.Range("A" & objWorksheet.Rows.Count).End(xlUp).Row
Set objOutlookApp = CreateObject("Outlook.Application")
Set objCalendar = objOutlookApp.Session.GetDefaultFolder(olFolderCalendar)
For nRow = 2 To nLastRow
Set objBirthdayEvent = objCalendar.Items.Add("IPM.Appointment")
'Create birthday events
With objBirthdayEvent
.Subject = objWorksheet.Range("A" & nRow) & Chr(39) & "s Birthday"
.Body = "Born " & Format(Int(objWorksheet.Range("B" & nRow)), "mmmm dd, yyyy")
.AllDayEvent = False
.Start = objWorksheet.Range("B" & nRow)
.BusyStatus = olFree
.ReminderSet = True
.ReminderMinutesBeforeStart = 4320
Set objRecurrencePattern = .GetRecurrencePattern
With objRecurrencePattern
.RecurrenceType = olRecursYearly
.PatternStartDate = objWorksheet.Range("B" & nRow)
.NoEndDate = True
End With
.Save
End With
Next
End Sub
The more we hear silence, the more we begin to think about our value in this universe.
Paraphrase of Professor Brian Cox.