How to stop error on Cancel event

[Glenley]

I have a global login function on several Form Open events that require the input of a password and if the password is incorrect, it will Cancel the open event. The function works fine but if the event is canceled, it throws an error; runtime '2501'. How do I prevent this error from occurring? I've tried the On Error GoTo Next but that didn't prevent it. Any help would be greatly appreciated

Public Function IsAdmin() As Boolean


    Dim AdminPass As String
    Dim MyPass As String
    
    MyPass = InputBox("Admin Level Security" & vbNewLine & "Enter Password")
    AdminPass = DLookup("AdminPassword", "SettingT")
    
    IsAdmin = False
    
    If AdminPass = MyPass Then
        IsAdmin = True
    Else
        IsAdmin = False
        MsgBox "Incorrect Password!", vbExclamation
    End If


End Function

Private Sub Form_Open(Cancel As Integer)


    If IsAdmin = False Then
        Cancel = True
        Exit Sub
    End If
    
End Sub

[CJ_London]

no idea what runtime error 2501 is, I just can't hold the thousands of codes in my head. So if the following doesn't answer your question, please provide the error description.

your code does not close the form so your error is probably happening further down the line in the load or current event, suggest you need the docmd.close function

[davegri]

Modify your code to include an error handler to trap and ignore the error, which is just an informational 'error'.

Private Sub Form_Open(Cancel As Integer)
    On Error GoTo Error_Handler
    If IsAdmin = False Then
        Cancel = True
        Exit Sub
    End If
Error_Handler_Exit:
    On Error Resume Next
    Exit Sub
Error_Handler:
    Select Case Err
        Case 2501   'ignore
        Case Else
            MsgBox "Error " & Err.Number & " (" & Err.Description & ")", vbExclamation, "Error in Sub Form_Open of Form_GetUserNameClientOnly"
    End Select
    Resume Error_Handler_Exit
End Sub

Change the red to your form name...

[Glenley]

I tried both examples and still getting the error

Run-Time Error '2501':
The OpenForm action was canceled

[Glenley]

Ajax, you were on the right track. I found that instead of Cancel=True, if I use DoCmd.Close I don't get the error. I'd still like to know why Cancel returns an error though

[davegri]

I tried both examples and still getting the error

Run-Time Error '2501':
The OpenForm action was canceled

Then the error is not caused by the form_open event being cancelled.
When the error occurs and you click Debug, what line of code is highlighted?

[Glenley]

On Debug the DoCmd.OpenForm is highlighted in the command button click event

[davegri]

On Debug the DoCmd.OpenForm is highlighted in the command button click event

Then that event is the procedure that needs the error handler code. That event code was not posted.

[Glenley]

This is the event

DoCmd.OpenForm "AdminF"

[Micron]

I'd still like to know why Cancel returns an error though

It's not really an error - it's information as noted above. Since flow will return to the calling sub (which you didn't post) when downstream procedures are complete, then IF the calling code depended on the form being open, all sorts of errors and problems could arise. So the calling code is 'notified' that the form isn't open thus the message. I simply trap the error number and move on so I agree with that suggestion FWIW.

[Glenley]

Okay I got it. I didn't post a line of code. My apologies. Thank you for the help everybody. Ajax, thank you for pointing me in the right direction. I really do appreciate it