Functions

[Alex Motilal]

Hi Everybody,

I am using the following Function in a module to return addresses in reports.



Function AddressBlock(strName, strAddress, strStreet, strArea, strCity, strPin) As String

Dim strFirstRow As String, strSecondRow As String, strThirdRow As String
Dim strFourthRow As String, strFifthRow As String, strHardReturn As String

strFirstRow = NulltoString(strName)
strSecondRow = NulltoString(strAddress)
strThirdRow = NulltoString(strStreet)
strFourthRow = NulltoString(strArea)
strFifthRow = strCity & " - " & strPin

AddressBlock = strFirstRow & strSecondRow & strThirdRow & strFourthRow & strFifthRow

End Function

Function NulltoString(Optional strCheckValue) As String

If IsNull(strCheckValue) Then
NulltoString = ""
Else
NulltoString = strCheckValue & Chr(13) & Chr(10)
End If
End Function

What I need is that the First row should be in heavy font and the Fifth row should also be in heavy font and underlined.

Can enyone suggest what code should I add to get the desired result?

With thanks
Alex

[ChrisO]

Five text boxes named txtRow0 to txtRow4.
Each set to can shrink.
Format each as you see fit.

Private Sub PageHeaderSection_Format(Cancel As Integer, FormatCount As Integer)
    Dim strAddress() As String
    Dim intIndex     As Integer

    strAddress = Split(AddressBlock("Some Name", _
                                    "Some Address", _
                                    "Some Street", _
                                    "Some Area", _
                                    "Some City", _
                                    "Some Pin"), vbCrLf)
    
    For intIndex = LBound(strAddress) To UBound(strAddress)
        Me("txtRow" & CStr(intIndex)) = strAddress(intIndex)
    Next intIndex
    
End Sub


Function AddressBlock(strName, strAddress, strStreet, strArea, strCity, strPin) As String
    Dim strFirstRow As String, strSecondRow As String, strThirdRow As String
    Dim strFourthRow As String, strFifthRow As String
    
    strFirstRow = NulltoString(strName)
    strSecondRow = NulltoString(strAddress)
    strThirdRow = NulltoString(strStreet)
    strFourthRow = NulltoString(strArea)
    strFifthRow = strCity & " - " & strPin
    
    AddressBlock = strFirstRow & strSecondRow & strThirdRow & strFourthRow & strFifthRow

End Function


Function NulltoString(Optional strCheckValue) As String

    If IsNull(strCheckValue) Then
        NulltoString = "" & Chr(13) & Chr(10)
    Else
        NulltoString = strCheckValue & Chr(13) & Chr(10)
    End If
    
End Function

HTH

Chris.

[weekend00]

What I need is that the First row should be in heavy font and the Fifth row should also be in heavy font and underlined.

you can not put different style for different lines in one textbox,
you need to design one textbox for each line. then set the first and the fifth textbox to the style/font as you want.