Double click event NOT firing in a continous form ??

[ksor]

I'm using Office 365 Home version.

In most of my continous forms I have a field with a file name in it. The content of the file and why I have such a file name is not importent to this problem.

When I double click the field the file name in that field is used to open the file in Word, Excel ect, ect. - and it works nicely - EVEN if focus is on one record and I double click the field on ANOTHER record.

I now have 1 form where it seems NOT to work in that latter situation:

If focus is on ONE record and I double click the field on ANOTHER record - the file does NOT open - focus just moves to that record !

I have to single click to select the other record and THEN double click - then it works !!!!!!!

The ONLY difference I can see is that it WORKS when the continous form in in a SUBform and will NOT work when the continous form is not in a subform !

I don't think that's "by design" so what do I do wrong here ?



Unfortunately the DB is way too big to share !

The is nothing special to decode in the events, I think ...

The problem could be rephrased, I think - why does a double click event ONLY fire in a textbox in a continous form when the record is in focus ?

[ranman256]

what is the code behind the Dbl-click event?
what is the contents of the failed textbox?
is it a hyperlink or just text?

[Minty]

why does a double click event ONLY fire in a textbox in a continuous form when the record is in focus ?

Having just done some testing on both some subforms, and a straightforward continuous form, I can't replicate this behavior.
That would indicate something else is happening, so what other events are set to trigger in that detail / form?

[Minty]

Cross posted here https://www.utteraccess.com/forum/in...ic=2053046&hl=

[ksor]

and ......

[Minty]

Please have a read here https://www.excelguru.ca/content.php?184

[ksor]

Having just done some testing on both some subforms, and a straightforward continuous form, I can't replicate this behavior.
That would indicate something else is happening, so what other events are set to trigger in that detail / form?

I think the PROBLEM is in the continous form NOT in the sub forms and here is the ONLY two events I have in the main form where the problem actually is:

Private Sub Sti_til_fil_KeyDown(KeyCode As Integer, Shift As Integer)
    Select Case KeyCode
        Case vbKeyReturn
            If Me.ActiveControl = Me.Sti_til_fil Then
                Sti_til_fil_DblClick Cancel
            Else
            End If
    End Select
End Sub

Private Sub Sti_til_fil_DblClick(Cancel As Integer)
   If Not ErAngivet(Me.Sti_til_fil) Then
     If Not ErAngivet(Me.Benævnelse) Then
        FejlMeld ("Der skal angives BÅDE benævnelse OG notat !")
        Me.Benævnelse.SetFocus
        Cancel = True
     Else
        Me.Sti_til_fil.Locked = False
        Me.Sti_til_fil.Text = "Notat-" & NotatID.Value & ".docx"
        Me.Sti_til_fil.Locked = True
        Set WRDobj = CreateObject("Word.Application")
'        WRDobj.Visible = False
        Set doc = WRDobj.Documents.add
        doc.Sections(1).Headers(wdHeaderFooterPrimary).Range.Text = "NotatID: " & Me.NotatID.Value & "-" & Me.Benævnelse.Value
        doc.SaveAs TrimFrom("Right", CurrentDb.Name, "\") & "NOTAT_docs\" & Me.Sti_til_fil.Text, wdFormatDocumentDefault
        WRDobj.Quit
        Set doc = Nothing
        Set WRDobj = Nothing
        OpenNativeApp TrimFrom("Right", CurrentDb.Name, "\") & "NOTAT_docs\" & Me.Sti_til_fil
     End If
   Else
     OpenNativeApp TrimFrom("Right", CurrentDb.Name, "\") & "NOTAT_docs\" & Me.Sti_til_fil
   End If
End Sub

Notice that a break point at these two subs will NOT stop the execution (ofcause not in the keydown event because I use the mouse !)

In ALL my other continous sub forms the execution STOPS at a break point at the double click event sub ... I think that prooves it has nothing to do with the code in the event sub - right ?

Please DO REMEMBER what the problem is ... double clicking in the textbox at a record WITHOUT focus !
(if I double click in the textbox at the record in focus ALL works nicely !)

The content of the textbox is just plain text ... just happened to be a file name.

[Minty]

From what you are saying then, the double click event is not being fired, as far as I can see the only thing that would cancel that is the Keydown code.
Comment it out and see if your problem goes away.

I'm actually puzzled by the keydown codes purpose?
By definition the control will be the active control if you are checking in it's own keydown event?
Or am I misreading things?

[ksor]

From what you are saying then, the double click event is not being fired, as far as I can see the only thing that would cancel that is the Keydown code.
Comment it out and see if your problem goes away.

I'm actually puzzled by the keydown codes purpose?
By definition the control will be the active control if you are checking in it's own keydown event?
Or am I misreading things?

The Keydown event is needed for users using the keyboard - so I can't just leave that out ...
but of cause I tried leaving it out for the test here, and it makes NO difference - still no double click event fired !

The two event subs I showed is for THE TEXTBOX itself !

The FORM has its own set of event subs but NOT for double click !

[Minty]

So show us the other form events, Current would be the obvious candidate. Any Detail section events?
They could all fire before your text control event if you aren't on that record before hand.

And please STOP shouting. I'm capable of reading your comments, and you haven't explained the logic of the code behind the keydown code, in plain English (and I appreciate that is not your native language) it reads to me as;

I'm on control A
Whilst on control A there is a keydown event
If that key press is return then
If the active control is control A ? (It must be, look at the event its attached to ?) then cancel the double click event??? What double click event???


So what is this achieving?

Private Sub Sti_til_fil_KeyDown(KeyCode As Integer, Shift As Integer)
    Select Case KeyCode
        Case vbKeyReturn
            If Me.ActiveControl = Me.Sti_til_fil Then
                Sti_til_fil_DblClick Cancel
            Else
            End If
    End Select
End Sub

[ksor]

So show us the other form events, Current would be the obvious candidate. Any Detail section events?
They could all fire before your text control event if you aren't on that record before hand.

And please STOP shouting. I'm capable of reading your comments, and you haven't explained the logic of the code behind the keydown code, in plain English (and I appreciate that is not your native language) it reads to me as;

I'm on control A
Whilst on control A there is a keydown event
If that key press is return then
If the active control is control A ? (It must be, look at the event its attached to ?) then cancel the double click event??? What double click event???


So what is this achieving?

Private Sub Sti_til_fil_KeyDown(KeyCode As Integer, Shift As Integer)
    Select Case KeyCode
        Case vbKeyReturn
            If Me.ActiveControl = Me.Sti_til_fil Then
                Sti_til_fil_DblClick Cancel
            Else
            End If
    End Select
End Sub

You're focusing om so many other things that has nothing to do with the problem - the more code you see, the more explanation you want and the keydown is NOT part of the problem here !

As I told I my last posting it's for users using the keyboard and if they do press Return it just starts the code in the Double click event - and it works nicely !
Maybe I copied it from somewhere else where more controls were involved and maybe it could be minimized a little more - I don't remember and it's completely irrelevant !

Here are event subs on FORM level - but nothing special here, I think :

Private Sub Form_Current()
    Me.txtHLId = NotatID
    Me.Sti_til_fil.SetFocus
    evtTilføjelser
End Sub

Private Sub evtTilføjelser()
    ' Notes can ONLY be added when
    ' specific type of notes are choosed
    Me.AllowAdditions = Not Me.chkType.OldValue
End Sub

Private Sub Form_Load()
    chkType.Value = True
    Me.Requery
End Sub

Private Sub Form_BeforeUpdate(Cancel As Integer)
    If Not ErAngivet(Me.Benævnelse) Or Not ErAngivet(Me.Sti_til_fil) Then
        FejlMeld ("Der skal angives BÅDE en benævnelse OG et notat !" & CrLf(1) & _
                  "Tryk evt. ESC for at få den gamle værdi tilbage !" & CrLf(2) & _
                  "Ellers skal HELE notatet slettes ved at klikke på " & CrLf(1) & _
                  "bjælken i venstre side af formularen og DELETE !")
    End If
End Sub

Private Sub Form_BeforeInsert(Cancel As Integer)
   Me.NotatTypeID = Me.cboNotatType.Column(0)
End Sub

Private Sub Form_Delete(Cancel As Integer)
    If Veto("Skal notatet overføres til mappen 'SLET_docs' ?", vbDefaultButton1) = vbYes Then
        flytFilTilSlet "NOTAT_docs\", Me.Sti_til_fil
    End If
End Sub

Private Sub Form_Open(Cancel As Integer)
    Call gfncCenterForm(Me)
    cboNotatType = cboNotatType.ItemData(0)
End Sub

Remember though even if a break point is inserted in both these event subs excecution is NOT stopped when performing af double click in the textbox on a record NOT in focus.
Execution IS stopped if you double click in the textbox on the focused record !

[Minty]

I suspect - and I haven't tested, but comment out the line in red ;

Private Sub Form_Current()
    Me.txtHLId = NotatID
    Me.Sti_til_fil.SetFocus
    evtTilføjelser
End Sub

I believe this will fire before your double click event, and is probably confusing it.

[ksor]

SOLVED !

Private Sub Form_Current()
    Me.txtHLId = NotatID
'    Me.Sti_til_fil.SetFocus
    evtTilføjelser
End Sub

commenting out the Setfocus solves the problem !

thx for you time !