Report Preview

[ColPat]

Hi,

I have a table with field EmployeeID. On a form (bound to the table) I have a combo box to lookup EmployeeID (from another table) and a command button to preview a report. I want to filter the report by the ID in the combo box.
With the code below I keep getting an input box asking for a parameter value popping up when I click the preview button, it shows the ID from the combo box.
How do I stop the input box and have the parameter passed directly to the DoCmd command line.
__________________________________________________ ___________
Private Sub cbEmployeeName_Click()

strName = Me!cbEmployeeName.Column(0)

End Sub
__________________________________________________ ___________
Private Sub coPreviewWOReport_Click()
On Error GoTo Err_coPreviewWOReport_Click

Dim stDocName As String
stDocName = "WOListing"
strFilter = "[EmployeeID]=" & strName
DoCmd.OpenReport stDocName, acPreview, , strFilter

Exit_coPreviewWOReport_Click:
Exit Sub

Err_coPreviewWOReport_Click:
MsgBox Err.Description
Resume Exit_coPreviewWOReport_Click

End Sub

[maximus]

if employee Id is supposed to be a Integer Field. but strName is a String.

I would rather have my code on the AfterUpdate Event of the ComboBox Like this:

Private Sub cbEmployeeName_AfterUpdate()

Dim strCriteria As String
Dim stDocName As String

stDocName = "WOListing"
strCriteria="[EmployeeID]=" & Me.cbEmployeeName.Column(0)
DoCmd.OpenReport stDocName, acPreview, , strCriteria
End Sub

Assuming the the column(0) holds the employee code which is a string
if the employee code is a string then

Private Sub cbEmployeeName_AfterUpdate()

Dim strCriteria As String
Dim stDocName As String

stDocName = "WOListing"
strCriteria="[EmployeeID]='" & Me.cbEmployeeName.Column(0) & "'"
DoCmd.OpenReport stDocName, acPreview, , strCriteria
End Sub

[ColPat]

Thanks Maximus
Employee is a string as has letters and numbers. Must have been the missing & and sintax on the setting the strFilter. Works a treat now.
Regards
Colin