TimerInterval in Form

[azhar2006]

Hello guys
I have used this code for the purpose of the appearance of the text boxes sequentially, but it did not work.
any help
thank you

Private Sub Form_Timer()
            If Me.TimerInterval = 1000 Then
               Me.txtTimer.Visible = True


            ElseIf Me.TimerInterval = 3000 Then
                Me.txtTimer1.Visible = True


            ElseIf Me.TimerInterval = 5000 Then
                Me.txtTimer2.Visible = True


            End If


End Sub

[JeroenMioch]

It should work, but havent tested it myself,

On one of my forms i do it this way though :

Paste this in a module :

'***************** Code Start *******************
' This code was originally written by Dev Ashish.
' It is not to be altered or distributed,
' except as part of an application.
' You are free to use it in any application,
' provided the copyright notice is left unchanged.
'
' Code Courtesy of
' Dev Ashish
'
Private Declare Sub sapiSleep Lib "kernel32" _
        Alias "Sleep" _
        (ByVal dwMilliseconds As Long)


Sub sSleep(lngMilliSec As Long)
    If lngMilliSec > 0 Then
        Call sapiSleep(lngMilliSec)
    End If
End Sub




'***************** Code End *********************

then use this on the form_timer event :

Const cTIME = 1000 'in MilliSeconds


Me.text1.Visible = True


Call sSleep(cTIME)


Me.text2.Visible = True
Const cTIME = 2000 'in MilliSeconds

'and so on

By setting the cTime to different values between the textboxes you can specify what time is between them for the textboxes
to appear.

[pbaldy]

TimerInterval is a property of the form. It does not change unless you change it. Sounds like you want to test for the passage of time, which your code will not do.

[Missinglinq]

As Paul said, TimerInterval is a Form Property that you set...not an elapsed time that can be Read. This is the kind of thing you need, assuming that you want each Control to become visible, in turn, after 1, 3 and 5 seconds have elapsed.

Private Sub Form_Load()
 Me.TimerInterval = 1000 'Timer Event will fire every Second
End Sub

Private Sub Form_Timer()

Static intCount As Integer
 
intCount = intCount + 1
  
  Select Case intCount

   Case 1 '1 second has passed
  
    Me.txtTimer.Visible = True

   Case 3  '3 seconds have passed
    
    Me.txtTimer1.Visible = True

    Case 5  '5 seconds have passed
     
     Me.txtTimer2.Visible = True
     
     intCount = 0

  End Select
            
End Sub

For this to work, the Visible Properties of each Control will have to originally be set to False/No, of course. And depending on your exact scenario, you may have to tweak this. You haven't said whether you want this to only happen when the Form originally opens, or each time a New Record is created, or what, exactly.

Linq ;0)>

[azhar2006]

Unfortunately, the delayed response
Thank you so much you guys