Issue with code opening another form to specific record ...

[mrmims]

Hello,

I have a form, "frm_Axis_Info", which has an unbound text box, "Axis_Search", the user can type in an Axis Number and press enter. It opens another form "frm_Axes" to this specific record.

It works great, except for the fact my users can not navigate through different records once "frm_axes" has opened. It only displays the record they were looking for and gives an error message ("You can't go to the specified record") if they try to navigate next or previous. There are hundreds of in "frm_Axes" but my code is limiting them only to the Axis Number they were looking for.

What am I doing wrong?

Private Sub Axis_Search_AfterUpdate()


If IsNull(Me.Axis_Search) Or Me.Axis_Search = "" Then


     MsgBox "Please enter an Axis Number"
     Me.Axis_Search.SetFocus
     Cancel = True
     Exit Sub
End If


If DCount("[AxisNumber]", "tbl_Axes", "AxisNumber = " & Me.Axis_Search) = 0 Then
     MsgBox "Please enter a Valid Axis Number"
     Me.[AxisNumber].SetFocus
     Cancel = True
     Exit Sub
End If


DoCmd.OpenForm "frm_Axes", , , "AxisNumber = " & Me.Axis_Search


DoCmd.Close acForm, "frm_Axis_Info"


End Sub

Thank you for your help

[June7]

Nothing wrong, that is the correct behavior for the code.

Why do you have to open another form to view record? Isn't it already available on the first form?

[mrmims]

Hi and thank you for the help,

"frm_Axis_Info" is a menu with many buttons leading to other reports and forms regarding information about the Axes.

I have an unbound text box, "Axis_Search", on this form which allows to the user to enter in an Axis number, press enter, and open "frm_axes" directly to the specific Axis record.

How can I change the code to have the "frm_Axes" still open to the specific record, BUT also allow the user to navigate between records and not just limit them to the record searched?

Thank you

[June7]

Options:

1. Maybe button on frm_Axes that removes the filter criteria from the Filter property and/or sets the FilterOn property to False

2. Open frm_Axes without filter and use code that moves to the desired record - this is a bit more complicated and probably more than one way to accomplish.

Don't open form with filter, pass criteria with OpenArgs
DoCmd.OpenForm "frm_Axes", , , , , , Me.Axis_Search

Code in frm_Axes Load or Open event to either set Filter and FilterOn properties (along with button in 1 to unset).

Or if form opens with focus on AxisNumber control, try:
DoCmd.FindRecord Me.OpenArgs, , , , , acCurrent

Or if AxisNumber control cannot have focus, try:
Me.RecordsetClone.FindFirst "AxisNumber=" & Me.OpenArgs
If Not Me.RecordsetClone.NoMatch Then
Me.Bookmark = Me.RecordsetClone.Bookmark
End If

[mrmims]

Removing the filter was the way to go!!! Thank you so much. This is the code I use when opening the form "On Load".

[Code]
If Me.FilterOn = True Then
Dim valFN As String
valFN = Me.AxisNumber
Me.FilterOn = False
DoCmd.GoToControl "AxisNumber"
DoCmd.FindRecord valFN
End If
[Code/]