Getting an error and don't know why

[brandonze]

Here is the code that I am running

Private Sub txtIncomingBarcode_AfterUpdate()
On Error GoTo txtIncomingBarcode_AfterUpdate_Error
Me.txtDesiredCode = Mid([txtIncomingBarcode], 2, 6)


Me.test = B32toBin([txtDesiredCode], 10)
Debug.Print Me.test & " at " & Now()
DoCmd.OpenForm "Consolidated Signin Form", , , "SSN ='" & Me.test & "'"
On Error GoTo 0
Exit Sub
txtIncomingBarcode_AfterUpdate_Error:
MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure txtIncomingBarcode_AfterUpdate of VBA Document Form_Form13"
End Sub
Private Sub txtIncomingBarcode_BeforeUpdate(Cancel As Integer)
'This is where the Original Barcode gets placed when the employee's
'card is scanned.
On Error GoTo txtIncomingBarcode_BeforeUpdate_Error
If Me.txtIncomingBarcode = vbNullString Then
MsgBox "There must be a barcode in txtIncomingBarcode"
End If
On Error GoTo 0
Exit Sub
txtIncomingBarcode_BeforeUpdate_Error:
MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure txtIncomingBarcode_BeforeUpdate of VBA Document Form_Form13"
End Sub


It works great to scan in the employee and pull the Employee ID from the card, But if I clear out all the fields in the form I get an error stating
Error 94 (invailid use of null) In procedure txtIncomingBarcodeAfterUpdate of vba document form_form13.


Any guesses as to why I am getting this? Any fixes?

I would like to be able to clear this out so another barcode can be scanned.

[RuralGuy]

A couple of suggestions:

Private Sub txtIncomingBarcode_AfterUpdate()
   On Error GoTo txtIncomingBarcode_AfterUpdate_Error
   If Len(Me.txtIncomingBarcode & "") > 0 Then
      Me.txtDesiredCode = Mid([txtIncomingBarcode], 2, 6)
      Me.Test = B32toBin([txtDesiredCode], 10)
      Debug.Print Me.Test & " at " & Now()
      DoCmd.OpenForm "Consolidated Signin Form", , , "SSN ='" & Me.Test & "'"
      On Error GoTo 0
   End If
   Exit Sub
txtIncomingBarcode_AfterUpdate_Error:
   MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure txtIncomingBarcode_AfterUpdate of VBA Document Form_Form13"
End Sub
Private Sub txtIncomingBarcode_BeforeUpdate(Cancel As Integer)
'This is where the Original Barcode gets placed when the employee's
'card is scanned.
   On Error GoTo txtIncomingBarcode_BeforeUpdate_Error
   If Me.txtIncomingBarcode = vbNullString Then
      MsgBox "There must be a barcode in txtIncomingBarcode"
      Cancel = True
   End If
   On Error GoTo 0
   Exit Sub
txtIncomingBarcode_BeforeUpdate_Error:
   MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure txtIncomingBarcode_BeforeUpdate of VBA Document Form_Form13"
End Sub

[brandonze]

Thanks, Works great.

[RuralGuy]

Glad we could help.