Update form from another form

[rwahdan1978]

I have a main form that displays an image of one person. Based on that I am clicking a button that will take me to another form. The other form I am doing something else and when done:



I want to go back to the first form and run the load event again (note: the first form was left open when going to the second form).

How to do that?

     Dim rs2 As Recordset
     If (thecounterAll = 6) Then
        DoCmd.OpenQuery "reset UserChoice"
        thecounterAll = 1
        Set rs2 = CurrentDb.OpenRecordset("randomUser")
        Me.theuserid.Value = rs2!UserID
        Me.thename.Value = rs2!UserName
        Me.Image6.Picture = rs2!Photo
        DoCmd.OpenQuery "updateUserChoice"
        thecounterAll = thecounterAll + 1
        rs2.Close
        Set rs2 = Nothing
    Else
        Set rs2 = CurrentDb.OpenRecordset("randomUser")
        Me.theuserid.Value = rs2!UserID
        Me.thename.Value = rs2!UserName
        Me.Image6.Picture = rs2!Photo
        DoCmd.OpenQuery "updateUserChoice"
        thecounterAll = thecounterAll + 1
        rs2.Close
        Set rs2 = Nothing
    End If

Here where i move to the other form:

Private Sub ahmad100_Click()
    askedAhmadNum = 1
    DoCmd.OpenForm "form1"
End Sub

it is only done once as a page load but I want to reload the page before entering from the other form, here is what i did in the other form:

If (closetheform = -1) Then
        DoCmd.Close acForm, "form1"
        Forms![Main].Requery
End If

where the first form is called Main. Requery is not acting as a reload, I also did Refresh as well no lock!

[Bob Fitz]

You could open the second form as Dialog. The code would stop running when the second form opens and would resume when the second form closes. Then call the first forms load event:-

Private Sub ahmad100_Click()
    askedAhmadNum = 1
    DoCmd.OpenForm "form1" , , , , , acDialog 
    Call Form_Load
End Sub

[Welshgasman]

If you want to run the load event of the first form again, why not just close it when you go to the second form and then open it when you close the second form?

[Micron]

I don't see how a reload is going to help if a requery doesn't.
What is the difference between the If and the Else? It just looks like a repeat to me.
Shouldn't matter, but once the choice is made doesn't it make more sense to requery the main form then close form1 rather than close and hope the requery line still executes?

[rwahdan1978]

I don't see how a reload is going to help if a requery doesn't.
What is the difference between the If and the Else? It just looks like a repeat to me.
Shouldn't matter, but once the choice is made doesn't it make more sense to requery the main form then close form1 rather than close and hope the requery line still executes?

There is a difference as the counter is less than 6.

[Micron]

What I'm saying is, form load event loads records from the form recordsource. A requery does that too. If what you show in that code is the load event, then you should make that clear. For all I know, it's something else. Either way, it looks like you load the same recordset, so no need to type that out 2x.

If you want to run a control, form or report event from some other form, usually all you have to do is make it Public, and not Private, which it is by default. I can't recall the exact syntax of the call. I think it follows the form name as shown in the vbe project pane, like form_frmMain (or whatever the form name is). I believe you must leave off the () at the end of the procedure name.

EDIT - BTW, if counter is 6 and you reset to 1, do you immediately want it to become 2? That's what you'll be doing.

[Welshgasman]

Any time you repeat code, there is normally a better clearer way.

[moke123]

There is a difference as the counter is less than 6.

What's the difference?

Another slightly more complicated method and probably overkill is to use custom events.
All the code below goes in the main form and the events are handled in the main forms module.

Dim WithEvents MyForm as access.form   ' this goes in the header of form Main

Private Sub ahmad100_Click()
 
     DoCmd.OpenForm "form1"   'open the form

     Set MyForm = Forms("form1")  'create an instance

     MyForm.OnClose = "[Event Procedure]"  'ensure an event.  You can use most form events here instead of OnClose

End Sub

Private Sub MyForm_Close()

     'do what you want here when form1 closes

     Me.Requery

     Set MyForm = Nothing  ' destroy instance

End sub

[Micron]

What's the difference?

A query is opened: DoCmd.OpenQuery "reset UserChoice" and the counter becomes 2 instead of just incrementing. That doesn't make it necessary to write the rest of it 2x.

[moke123]

A query is opened: DoCmd.OpenQuery "reset UserChoice" and the counter becomes 2 instead of just incrementing. That doesn't make it necessary to write the rest of it 2x.

Re-formatted and now I see it.

      Dim rs2 As Recordset    

     Set rs2 = CurrentDb.OpenRecordset("randomUser")
     
    If (thecounterAll = 6) Then
     
        DoCmd.OpenQuery "reset UserChoice"
        
        thecounterAll = 1
                
    End If
     
    DoCmd.OpenQuery "updateUserChoice"
    
     thecounterAll = thecounterAll + 1
    
    Me.theuserid.value = rs2!UserId
    Me.thename.value = rs2!UserName
    Me.Image6.Picture = rs2!Photo


    rs2.Close
    Set rs2 = Nothing

[moke123]

As far as returning to the main form, are you trying to do something like this?

Open the form1, enter some info, and then return to the same record on form main with the new info showing?