Add error code for export VBA if PDF is already open?

[templeowls]

I have code for a button that exports a report to a PDF. It works flawlessly, however some users have trouble with it. These users export this report a couple times a day and save over the previous pdf under the same name, and unfortunately, they sometimes leave the previous PDF open. This doesn't allow access to overwrite it and access then shows a 2501 output error.

No matter how many times I tell them, these users think that this error means something is wrong with access and not the fact that they have a pdf open that they are trying to overwrite. Can anyone help modify my code so that it handles this error with a simple "hey the pdf is open" message instead of the 2501 output error message? Thanks!

Private Sub btnExportReport_Click()    
    Dim reportName As String
    Dim fd As Object
    Dim filename As String
   
    reportName = "rptComplaintReview"


    Set fd = Application.FileDialog(2)
    filename = "Complaint Review" & " " & Format(Date, "mm.dd.yyyy") & ".pdf"
    
    With fd
        .Title = "Save to PDF"
        .InitialFileName = "\Documents\" & filename
        If .Show = -1 Then
            filename = fd.SelectedItems(1)
            If InStr(filename, ".") = 0 Then
                filename = filename & ".pdf"
            ElseIf Right(filename, 4) <> ".pdf" Then
                k = InStrRev(filename, ".") - 1
                filename = Left(filename, k)
                filename = filename & ".pdf"
            End If
        
        DoCmd.OutputTo acOutputReport, reportName, acFormatPDF, filename


        MsgBox "Report saved to " & filename
        
        End If
    
    End With


    Set fd = Nothing
End Sub

[June7]

For error handling example, review http://allenbrowne.com/ser-23a.html

[kd2017]

Private Sub btnExportReport_Click()
On Error GoTo ErrHandler
    Dim reportName As String
    Dim fd As Object
    Dim filename As String
   
    reportName = "rptComplaintReview"


    Set fd = Application.FileDialog(2)
    filename = "Complaint Review" & " " & Format(Date, "mm.dd.yyyy") & ".pdf"
    
    With fd
        .Title = "Save to PDF"
        .InitialFileName = "\Documents\" & filename
        If .Show = -1 Then
            filename = fd.SelectedItems(1)
            If InStr(filename, ".") = 0 Then
                filename = filename & ".pdf"
            ElseIf Right(filename, 4) <> ".pdf" Then
                k = InStrRev(filename, ".") - 1
                filename = Left(filename, k)
                filename = filename & ".pdf"
            End If
        
        DoCmd.OutputTo acOutputReport, reportName, acFormatPDF, filename


        MsgBox "Report saved to " & filename
        
        End If
    
    End With
    
ExitHandler:
    Set fd = Nothing
    Exit Sub
    
ErrHandler:
    If Err.Number = 2501 Then
        MsgBox "Hey the pdf is already open, knucklehead."
    Else
        MsgBox "Error #" & Err.Number & " - " & Err.Description, , "Export Error"
    End If
    
    Resume ExitHandler
End Sub

[templeowls]

Private Sub btnExportReport_Click()
On Error GoTo ErrHandler
    Dim reportName As String
    Dim fd As Object
    Dim filename As String
   
    reportName = "rptComplaintReview"


    Set fd = Application.FileDialog(2)
    filename = "Complaint Review" & " " & Format(Date, "mm.dd.yyyy") & ".pdf"
    
    With fd
        .Title = "Save to PDF"
        .InitialFileName = "\Documents\" & filename
        If .Show = -1 Then
            filename = fd.SelectedItems(1)
            If InStr(filename, ".") = 0 Then
                filename = filename & ".pdf"
            ElseIf Right(filename, 4) <> ".pdf" Then
                k = InStrRev(filename, ".") - 1
                filename = Left(filename, k)
                filename = filename & ".pdf"
            End If
        
        DoCmd.OutputTo acOutputReport, reportName, acFormatPDF, filename


        MsgBox "Report saved to " & filename
        
        End If
    
    End With
    
ExitHandler:
    Set fd = Nothing
    Exit Sub
    
ErrHandler:
    If Err.Number = 2501 Then
        MsgBox "Hey the pdf is already open, knucklehead."
    Else
        MsgBox "Error #" & Err.Number & " - " & Err.Description, , "Export Error"
    End If
    
    Resume ExitHandler
End Sub

THis worked! Thanks so much