Radio Buttons Problem

[luckydead]

Hello i'm having problem with radio buttons.

I have added from Option Group wizzard, my radio buttons, named them correctly.
And i want to make an check when press the button, if no radio button was selected to show message please select button first.

But i have a problem with error message: you entered an expression that has no value

[Minty]

And what was you code generating the error?

Also consider giving the option group a default value, then there can never be case when one isn't selected.

[luckydead]

When i click on each radio button i have values like 1,2,3,4,5,so one to the end radio button


in my code of button is like this:

Private Sub Command21_Click()
On Error GoTo Err_Command21_Click

Err_Command21_Click:
    MsgBox Err.Description
    Resume Exit_Command21_Click
    
End Sub

And here it shows this error message: you entered an expression that has no value

Also in Frame41 in properties i set up default value to 1:
and still shows the same error message:

[Welshgasman]

You do not have a label called ?
Exit_Command21_Click

Why have you even got that event code, it does nothing?

[Minty]

That code doesn't do anything?
Assuming Command21_Click is the button you are clicking to do something then you would need code along the lines of;

Private Sub Command21_Click()

     Msgbox "My option group value is " &  NZ(Me.Frame41, "Null Value") 

    
End Sub

Does that make sense?

[luckydead]

full code of button:

Private Sub Command21_Click()
On Error GoTo Err_Command21_Click


If Text19.value = "" Then
MsgBox "Please fill number of copies"
End If


Dim result As Integer


If Check_Print = True Then
result = 1
End If
    
    If line1_chk.value = -1 Then
    CheckTable ("W177-L")
     If showme = 1 Then
      MsgBox "Result is: " & showme
        'DoCmd.OpenReport "Print_W177-L", acViewPreview
        'If result = 1 Then
        'DoCmd.PrintOut , , , , Text19.Value, False
        'End If
      Else
      MsgBox "Result is: " & showme
     End If
    End If
    
    If line2_chk = True Then
        DoCmd.OpenReport "Print_H247-L", acViewPreview
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If
    
    If line3_chk = True Then
        DoCmd.OpenReport "Print_W177-R", acViewPreview
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If
    
    If line4_chk = True Then
    'Lets check combined Lines shitss pff..
    If MsgBox("Click Yes for V177-L or No for W177-L !", vbYesNo + vbQuestion) = vbYes Then
    DoCmd.OpenReport "Print_V177-L", acViewPreview
    Else
    DoCmd.OpenReport "Print_W177-L", acViewPreview
    End If
    'end this shit...
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If
    
    If line5_chk = True Then
        DoCmd.OpenReport "Print_W247-L", acViewPreview
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If
    
    If line6_chk = True Then
        DoCmd.OpenReport "Print_H243-L", acViewPreview
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If
    
    If line7_chk = True Then
    'Lets check combined Lines shitss pff..
    If MsgBox("Click Yes for H247-R or No for W247-B !", vbYesNo + vbQuestion) = vbYes Then
    DoCmd.OpenReport "Print_H247-R", acViewPreview
    Else
    DoCmd.OpenReport "Print_W247-R", acViewPreview
    End If
    'end this shit...
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If
    
    If line8_chk = True Then
    'Lets check combined Lines shitss pff..
    If MsgBox("Click Yes for H243-R or No for V177-R !", vbYesNo + vbQuestion) = vbYes Then
    DoCmd.OpenReport "Print_H243-R", acViewPreview
    Else
    DoCmd.OpenReport "Print_V177-R", acViewPreview
    End If
        'end this shit...
        If result = 1 Then
        DoCmd.PrintOut , , , , Text19.value, False
        End If
    End If


Exit_Command21_Click:
    Exit Sub


Err_Command21_Click:
    MsgBox Err.Description
    Resume Exit_Command21_Click
    
End Sub

[Welshgasman]

So walk through the code line by line to see where the error occurs. As the code looks copied, if on first radio button, likely on others?

[luckydead]

even if i do it like this same error:

Private Sub Command21_Click()
On Error GoTo Err_Command21_Click


If Text19.value = "" Then
MsgBox "Please fill number of copies"
End If


Dim result As Integer


If Check_Print = True Then
result = 1
End If
    
    If line1_chk.value = -1 Then
    CheckTable ("W177-L")
     If showme = 1 Then
      MsgBox "Result is: " & showme
        'DoCmd.OpenReport "Print_W177-L", acViewPreview
        'If result = 1 Then
        'DoCmd.PrintOut , , , , Text19.Value, False
        'End If
      Else
      MsgBox "Result is: " & showme
     End If
    End If
    
    


Exit_Command21_Click:
    Exit Sub


Err_Command21_Click:
    MsgBox Err.Description
    Resume Exit_Command21_Click
    
End Sub

[Minty]

What is text19 ?
Is it a combo, a textbox, a date field, and option group?

It's really helpful if you call controls names that vaguely indicate their purpose. Names like

txtMyValue
cboMySelection
txtReportDate
optPrintCopies

Would make all you code a lot easier to understand both for you and outsiders.

You aren't referencing the option group (Frame41) anywhere as far as I could see?

[luckydead]

it is textbox that will store value 1 or 2 or other number

Anyway i remove the radio buttons i think it would be good, but better was make checkboxes and add + if one checkbox is enable disable the others and work like a charm no problems with check boxes.

[Minty]

I think your code could be much simpler with the use a select case structure to set some variables and then simply print or preview based the variables you set earlier in the code.

[Minty]

If you go back to your option button group you can simplify your code to this;

Private Sub Command21_Click()    
    Dim sTable          As String
    Dim sPrint          As String
            
    On Error GoTo Err_Command21_Click
    
    If (Val(Me.Text19) + 0) < 1 Then
        MsgBox "Please fill number of copies"
        Exit Sub
    End If


    Select Case Me.optLines
    
        Case 1
            sTable = "W177-L"
            MsgBox "Result is: " & showme
            Exit Sub

        Case 2
            sPrint = "Print_H247-L"
            
        Case 3
            sPrint = "Print_W177-R"
        
        Case 4
            If MsgBox("Click Yes for V177-L or No for W177-L !", vbYesNo + vbQuestion) = vbYes Then
                sPrint = "Print_W177-R"
            Else
                sPrint = "Print_W177-L"
            End If
            '
        Case 5
            sPrint = "Print_W247-L"
    
        Case 6
            sPrint = "Print_H243-L"
        
        Case 7
            If MsgBox("Click Yes for H247-R or No for W247-B !", vbYesNo + vbQuestion) = vbYes Then
                sPrint = "Print_H247-R"
            Else
                sPrint = "Print_W247-R"
            End If
        Case 8
            If MsgBox("Click Yes for H243-R or No for V177-R !", vbYesNo + vbQuestion) = vbYes Then
                sPrint = "Print_H243-R"
            Else
                sPrint = "Print_V177-R"
            End If
            
    End Select
       
    DoCmd.OpenReport sPrint, acViewPreview


    If CheckPrint Then DoCmd.PrintOut , , , , Me.Text19, False


Exit_Command21_Click:
    Exit Sub




Err_Command21_Click:
    MsgBox Err.Description
    Resume Exit_Command21_Click
    
End Sub

You could easily add extra options to get rid of the other message boxes.