Facing problem Button Next and Previous Nor working after getting specific record

[ijaz8883]

Hi
I am Facing problem Button Next and Previous Nor working after getting specific record "ID"
I have One Form/Report in which I have linked the ID to form
Now when I open second form by clicking on first form's ID its work perfect.
When enter ID in second Form to search its work perfect.
But when I work on Next and Previous button on second form its not work and get error, while If I directly open second form its navigation button worked perfect? Let me know what/where is the problem?
There is db sample attached where it can be checked by opening report and by clicking on report ID After opening the Form by clicking on ID the navigation buttons not work.
GotoNext Nor working if open Form through Report.zip

[isladogs]

You are opening the form filtered to the selected record. As a result there is only one record and you can't move to a previous or next ID.
If that's your intention, you need to change the code so it opens the form unfiltered then moves to the selected record

[ijaz8883]

You are opening the form filtered to the selected record. As a result there is only one record and you can't move to a previous or next ID.
If that's your intention, you need to change the code so it opens the form unfiltered then moves to the selected record

[Missinglinq]

Like this:

In the Primary Form:

Private Sub Go2SecondaryForm_Click()

 If Nz(Me.RecordID,"") <> "" Then
  DoCmd.OpenForm "Secondary Form", , , , , , Me.RecordID
 Else
  MsgBox "A RecordID Must Be Entered First!"
 End If

End Sub

In the Secondary Form:

Private Sub Form_Load()

Dim rst As Recordset

If Nz(Me.OpenArgs,"") <> "" Then

 Set rst = Me.RecordsetClone
 
 rst.FindFirst "[RecordID] = " & Me.OpenArgs 
 
   If Not rst.NoMatch Then
    Me.Bookmark = rst.Bookmark
   Else
    Msgbox "Matching Record Not Found!"
   End If

rst.Close
Set rst = Nothing

End If

End Sub

The above code assumes that RecordID is Numeric. If it is actually defined Text, replace the line

rst.FindFirst "[RecordID] = " & Me.OpenArgs

with

rst.FindFirst "[RecordID] = '" & Me.OpenArgs & "'"

You'll also need to replace Go2SecondaryForm with the actual name of your SecondaryForm.

Linq ;0)>

[isladogs]

Ijaz
Does linq's answer clarify the approach for you?

[ijaz8883]

Like this:

In the Primary Form:

Private Sub Go2SecondaryForm_Click()

 If Nz(Me.RecordID,"") <> "" Then
  DoCmd.OpenForm "Secondary Form", , , , , , Me.RecordID
 Else
  MsgBox "A RecordID Must Be Entered First!"
 End If

End Sub

In the Secondary Form:

Private Sub Form_Load()

Dim rst As Recordset

If Nz(Me.OpenArgs,"") <> "" Then

 Set rst = Me.RecordsetClone
 
 rst.FindFirst "[RecordID] = " & Me.OpenArgs 
 
   If Not rst.NoMatch Then
    Me.Bookmark = rst.Bookmark
   Else
    Msgbox "Matching Record Not Found!"
   End If

rst.Close
Set rst = Nothing

End If

End Sub

The above code assumes that RecordID is Numeric. If it is actually defined Text, replace the line

rst.FindFirst "[RecordID] = " & Me.OpenArgs

with

rst.FindFirst "[RecordID] = '" & Me.OpenArgs & "'"

You'll also need to replace Go2SecondaryForm with the actual name of your SecondaryForm.

Linq ;0)>

Oh Grate You have done it Wonderful!!!
Thanks a lot Its working Perfect 100% as I required.

[ijaz8883]

Ijaz
Does linq's answer clarify the approach for you?

Yes his method worked for me grate. I was much worried about this problem because I have to open the form manually and also from report and full form and now the problem solved.