Getting 2185 in VBA Code

[emhill57]

I Googled and found the code below to limit the number of characters that can be entered in an unbound textbox. I call this in the "On Change" event and "On KeyPress" event. In certain instances I get the 2185 error "You can't reference a property or method for a control unless the control has focus." I'm not sure what I'm doing wrong. I do not have a .SetFocus anywhere. Any help?

================================================== ======
Sub LimitKeyPress(ctl As Control, iMaxLen As Integer, KeyAscii As Integer)
On Error GoTo Err_LimitKeyPress
' Purpose: Limit the text in an unbound text box/combo.
' Usage: In the control's KeyPress event procedure:
' Call LimitKeyPress(Me.MyTextBox, 12, KeyAscii)
' Note: Requires LimitChange() in control's Change event also.


If Len(ctl.Text) - ctl.SelLength >= iMaxLen Then
If KeyAscii <> vbKeyBack Then
KeyAscii = 0
Beep
End If
End If


Exit_LimitKeyPress:
Exit Sub


Err_LimitKeyPress:


'Call LogError(Err.Number, Err.Description, "LimitKeyPress()")
MsgBox "Error " & Err.Number & ": " & Err.Description
Resume Exit_LimitKeyPress
End Sub


Sub LimitChange(ctl As Control, iMaxLen As Integer)
On Error GoTo Err_LimitChange
' Purpose: Limit the text in an unbound text box/combo.
' Usage: In the control's Change event procedure:
' Call LimitChange(Me.MyTextBox, 12)
' Note: Requires LimitKeyPress() in control's KeyPress event also.


If Len(ctl.Text) > iMaxLen Then
MsgBox "Truncated to " & iMaxLen & " characters.", vbExclamation, "Too long"
ctl.Text = Left(ctl.Text, iMaxLen)
ctl.SelStart = iMaxLen
End If


Exit_LimitChange:
Exit Sub


Err_LimitChange:
'Call LogError(Err.Number, Err.Description, "LimitChange()")
MsgBox "Error " & Err.Number & ": " & Err.Description
Resume Exit_LimitChange
End Sub
================================================== ======

[pbaldy]

The .Text property requires focus, so if you passed it a control that didn't have focus you'd get that error.

[emhill57]

I have one unbound field in the header of the continuous form. It is used as a simple name filter on a form. It works just fine in that it will stop at the 30 character limit and when the filter button is clicked the form will filter correctly. The issue seems to happen when the filter text does not return any data. In that instance I click back into the textbox to re-enter another filter name and that is when I get the 2185 error. I've tried to SetFocus back to that control after the "Me.FilterOn = True" but it still gets the error. Any suggestions?

Thanks!!!!

[Micron]

Does the code stop and highlight a particular line? If not, change your settings in the vb editor to break on unhandled errors (Tools > Options). I suspect that if there is a break, it's not even in the code you posted, but in some other coded event for the control. I presume this

I click back into the textbox to re-enter another filter name and that is when I get the 2185 error.

means as soon as you click on it, and before you can type anything.

Please use code tags for anything more than just a few lines. When code breaks and highlights a line, indicate which line it is by adding a note to your code.
Thanks.

[emhill57]

Here is the code with code tags and where my error is happening:

Private Sub srch_name_KeyPress(KeyAscii As Integer)
    Call LimitKeyPress(Me.srch_name, 30, KeyAscii)
End Sub


Sub LimitKeyPress(ctl As Control, iMaxLen As Integer, KeyAscii As Integer)
On Error GoTo Err_LimitKeyPress
    ' Purpose:  Limit the text in an unbound text box/combo.
    ' Usage:    In the control's KeyPress event procedure:
    '             Call LimitKeyPress(Me.MyTextBox, 12, KeyAscii)
    ' Note:     Requires LimitChange() in control's Change event also.


    If Len(ctl.Text) - ctl.SelLength >= iMaxLen Then  '****Line in error****


        If KeyAscii <> vbKeyBack Then
            KeyAscii = 0
            Beep
        End If
    End If


Exit_LimitKeyPress:
    Exit Sub

When in debug the line I noted above is the where it stops.

[Micron]

Looks fine to me (with an oddity or two) so I tested your code. Seems to work if I enter 30 characters, click out of the control and back in to edit using either backspace or delete. I can't replicate your search function, so all I can think of is that you have other code that is diverting focus, or runs after the button click, such as a Lost_Focus or Got_Focus event, in which case you wouldn't be able to use the .Text property as noted.

So the oddities:
- once you have left the textbox and click the button I see no reason to use the .Text property. As soon as you leave the control, whatever is in it has been "committed", thus the contents will become the .Value. In that case, why not just use If Len(ctl)
- I don't see where you pass the SelLength to the sub, nor calculate it in the sub, so it's always going to be zero.

Depending on your situation, this could be as simple as

Private Sub srch_name_BeforeUpdate(Cancel As Integer)
If Len(Me.srch_name) > 30 Then
  MsgBox "Too many"
  Cancel = True
End If
End Sub

or just use the control value instead of it's .Text property

[pbaldy]

once you have left the textbox and click the button I see no reason to use the .Text property. As soon as you leave the control, whatever is in it has been "committed", thus the contents will become the .Value. In that case, why not just use If Len(ctl)

What button? The code is running as the user types, so the .Text property is necessary. That said, using the before update event would be a way around the problem.

[emhill57]

That will work just great! Thanks!!!!

[emhill57]

By the way here is the site for the code I was trying to use to limit the keyed characters. Can you see any flaw why it would not work? Just curious now! :-)

http://allenbrowne.com/ser-34.html

Thanks!!!

[Micron]

What button? The code is running as the user types, so the .Text property is necessary. That said, using the before update event would be a way around the problem.

I took "when I press the filter button " to mean a command button. Poster probably meant ribbon button.