How to create a User Stamp

[boxsta]

Afternoon all.

I have my access db set up with various forms/subforms/tables and all the rest of it but the one thing I'm really getting stuck on is the ability to user stamp a field in a subform. I can do date & time with Now() but in the next field across I also want to be able to stamp the name of the user that is currently logged into the db.



Any ideas greatly appreciated. I'm no Access expert though, so I might struggle with code unless it's in simple terms

Thanks

[RayMilhon]

This is a section of Code that I got online that will get the Windows Username and/or computer name. Got it awhile ago and unfortunately don't remember exactly where. Hopefully another user here will recognize it and give the website. Once you've put this into Access you can call the functions from queries, Forms wherever you need them.

Option Compare Database
Option Explicit

Private Declare Function apiGetComputerName Lib "kernel32" Alias "GetComputerNameA" (ByVal lpBuffer As String, nSize As Long) As Long
Private Declare Function apiGetUserName Lib "advapi32.dll" Alias "GetUserNameA" (ByVal lpBuffer As String, nSize As Long) As Long


Public Function GetComputerName() As String
On Error Resume Next
    
    Dim lngLen As Long, lngX As Long
    Dim strCompName As String
    
    lngLen = 16
    strCompName = String$(lngLen, 0)
    lngX = apiGetComputerName(strCompName, lngLen)
    If lngX <> 0 Then
        GetComputerName = Left$(strCompName, lngLen)
    Else
        GetComputerName = "Unknown"
    End If

End Function

Public Function GetLoginName() As String
On Error Resume Next
    
    Dim lngen As Long
    Dim lngX As Long
    Dim strUserName As String
    
    strUserName = String$(254, 0)
    lngen = 255
    lngX = apiGetUserName(strUserName, lngen)
    
    If lngX <> 0 Then
        GetLoginName = Left$(strUserName, lngen - 1)
    Else
        GetLoginName = "Guest"
    End If

End Function

[alansidman]

Here is another solution that might work for you

http://www.datawright.com.au/access_..._in_access.htm

[boxsta]

Thanks guys, hopefully Ill get that working just as soon as I've deciphered the code :-)