Highlighting a word searched for in a form

[westfallbp]

I have a form based on a query that returns records on a form: Like "*" & [Type anything you wish to search] & "*"



Is it possible in MS Access that it highlights the word in the field to make it easier to locate. Some of the records returned in the field it searches can be several paragraphs long. I hope I communicated my question correctly. Would be like using find in ms word. Thanks, any help would be greatly appreciated.

[jojowhite]

Only Richtext format (Long Text) field can be highlighted.

[westfallbp]

It is set to Long Text in the table

[orange]

See this by Allen Browne.

[westfallbp]

See this by Allen Browne.

Thanks, It may work. I googled it also a few hours ago and watched a video on the find function but uses command button find first, find next, but it didn't search through all the records. Will get back to you if I can adapt Allen Browne's.

[orange]

There is a sample database on the linked page I recommended. Reviw the article and the associated database.

Here is the code to find and highlight the desired text.
I have modified code to bold and color the found text RED

Private Sub txtSearchText_AfterUpdate()
On Error GoTo Err_Handler
    'Purpose:   Filter, and highlight matches in txtSearchDisplay.
    Dim strField As String              'The field to search
    Dim strSearchValue As String        'The value to find
    Dim strControlSource As String      'ControlSource for displaying match.
    Const strcWildcard = "*"            'Some other back ends use %
    'HTML tags for highlighting matches. Could be just "<b>" and "</b>".
    'Using Bold and RED
    Const strcTagStart = "<b><font  color=""""red"""">"  'jed Feb 2025<----modified line
    Const strcTagEnd = "</font></b>"
    
    'Save any edits.
    If Me.Dirty Then
        Me.Dirty = False
    End If
    
    'Apply a filter only if user chose a field and a value.
    If IsNull(Me.cboField) Or IsNull(Me.txtSearchText) Then
        If Me.FilterOn Then
            Me.FilterOn = False
        End If
        Call ShowHide(Me.txtSearchDisplay, False)
    Else
        strField = "[" & Me.cboField & "]"  'Cope with spaces in field name.
        strSearchValue = Me.txtSearchText
        'Apply the filter
        Me.Filter = strField & " Like """ & strcWildcard & strSearchValue & strcWildcard & """"
        Me.FilterOn = True
        
        'Control Source for the text box to display matches.
        strControlSource = "=IIf(" & strField & " Is Null, Null, " & _
            "Replace(" & strField & ", """ & strSearchValue & """, """ & _
            strcTagStart & strSearchValue & strcTagEnd & """))"
        With Me.txtSearchDisplay
            .ControlSource = strControlSource
            .Visible = True
        End With
    End If

Exit_Handler:
    Exit Sub

Err_Handler:
    Call LogError(Err.Number, Err.Description, conMod & "txtSearchText_AfterUpdate")
    Resume Exit_Handler
End Sub

[jojowhite]

here is also a demo.
open form, sampleForm.

don't use Replace() function because this
will change the Case of your text.
If your search in small letters then if you have
same text in your field but in Capital letter, the
capital letter will be replaced with small letter.