Open Form Hide Access

[crimedog]

I want a window (Form) to Open and hide the rest of Access. I have:

Private Sub Form_Open(Cancel As Integer)
DoCmd.SelectObject acTable, , True
DoCmd.RunCommand acCmdWindowHide
End Sub

This just hides the Navigation Pane

Then when the Form is closed I want Access to come back

Private Sub Form_Close()
DoCmd.SelectObject acTable, , True
DoCmd.RunCommand acCmdWindowShownormal
End Sub

I get error on Shownormal
But if I press stop in the VBA window - the form closes and shows access normally

[June7]

Review links in https://www.accessforums.net/access/...ers-48543.html

[John_G]

In the On Open event use:

DoCmd.RunCommand acCmdWindowHide ' hides the navigation pane
DoCmd.ShowToolbar "ribbon", acToolbarNo ' hides the ribbon

and in the On Close event use:

DoCmd.ShowToolbar "ribbon", acToolbarYes ' Restores the ribbon
DoCmd.SelectObject acForm, "", True ' Restores the navigation pane

[Missinglinq]

John_G's given you working code, but FYI, the reason

DoCmd.RunCommand acCmdWindowShownormal

popped an error is that

acCmdWindowShownormal

is not a valid Command, at least not through v2007, and I can find no reference to it anywhere, for later versions.

If you enter this kind of thing manually, as was done here by you, or by someone else (if you did the old 'copy and paste routine') rather then using IntelliSense (the autocomplete function in the Access VBA IDE) when you move off of the line of code the Access Gnomes will capitalize the beginning character of each word in the Command. So your

DoCmd.RunCommand acCmdWindowShownormal

would have become

DoCmd.RunCommand acCmdWindowShowNormal

The fact that this didn't occur, in this case, tells you that it wasn't a legitimate Command, which makes this a good test for the legitimacy of a Command that is entered 'freehand.'

Best policy, of course, unless you write this kind of code all the time, and I mean all the time, is to always use IntelliSense. When you type in DoCmd.RunCommand and hit the Space Key, a box will pop up with a list of all of the legitimate Commands.

Linq ;0)>

[crimedog]

Yes it was cut and paste - so I went to the code that June7 linked. I think I followed the steps exactly
But the VBA gets the error Sub or Function not defined with line that begins public function fAccesswindow... highlighted

Sub basAccessHider()
Private Declare Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long
Dim dwReturn As Long
Const SW_HIDE = 0
Const SW_SHOWNORMAL = 1
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3
Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, _
     ByVal nCmdShow As Long) As Long
     
Public Function fAccessWindow(Optional Procedure As String, Optional SwitchStatus As Boolean, Optional StatusCheck As Boolean) As Boolean
If Procedure = "Hide" Then
    dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
End If
If Procedure = "Show" Then
    dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
End If
If Procedure = "Minimize" Then
    dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMINIMIZED)
End If
If SwitchStatus = True Then
    If IsWindowVisible(hWndAccessApp) = 1 Then
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
    Else
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
    End If
End If
If StatusCheck = True Then
    If IsWindowVisible(hWndAccessApp) = 0 Then
        fAccessWindow = False
    End If
    If IsWindowVisible(hWndAccessApp) = 1 Then
        fAccessWindow = True
    End If
End If
End Function

Note: Both lines that read Private declare function... are in red font

[John_G]

That code will not compile. You cannot declare a function inside a Sub, and the code you show has no End Sub line, either.

[June7]

Remove the line Sub basAccessHider().

basAccessHider is supposed to be name of the module, not a Sub. This would be the name that shows in the Navigation pane for Access and the project list window of VBA editor. But name the module whatever you want.