Code not working!!

[jfn15]

I have 2 M:M relationships, as follows:



tblApplication, - AppID, AppDate etc.
tblAnimalDetails - AnimalID, Gender etc.
tblAppSpecies - AppID, AnimalID, SpeciesStatus etc.
tblContacts - ContactID, etc
tblContactApp - AppID, ContactID

I have an application form (frmApplication) that is based on a query (using tblApplication, tblContacts, tblContactApp)
I have a second form (frmAppSpecies), based on a query using tblAppSpecies & tblAnimalDetails. This is a form with a subform.
I've placed a command button on frmApplication, to open frmAppSpecies, with the AppID already added, so that relevant animal information for that particular application can be added.

The code I've put in the button's click event is as follows:


DoCmd.OpenForm "frmAppSpecies", acNormal, , "AppID =" & Me.AppID, acFormEdit, acDialog

I have no coding experience at all, so have cobbled this together from a book, but I'm obviously missing something - can anyone assist?

[orange]

It would be better for readers if you could post a jpg of your tables and relationships.
If you really have M:M relationships, you may find this video tutorial useful

https://www.youtube.com/watch?v=7XstSSyG8fw

Here is another tutorial (pdf based) to help with Tables, Normalization and Relationships.
http://www.rogersaccesslibrary.com/T...lationship.zip

[Dunro]

The code I've put in the button's click event is as follows:

DoCmd.OpenForm "frmAppSpecies", acNormal, , "AppID =" & Me.AppID, acFormEdit, acDialog

I'm assuming that the underlying query for frmApplication only includes 1 field called AppID? (even though it's used to join both tblApplication and tblContactApp). Also, if you have a control called AppID, is it bound to the correct field?

[JrMontgom]

You may need to be specific as to which AppID you mean i.e. precede the AppID field name with the table name for example tbl!.Appid to prevent confusion.

[Missinglinq]

...I've placed a command button on frmApplication, to open frmAppSpecies, with the AppID already added, so that relevant animal information for that particular application can be added...

Your code assumes that a Record for the given AppID already exists in frmAppSpecies, and that you want to go to that Record when that Form opens; is that the case?

Or do you need to go to frmAppSpecies and start a New Record with that AppID entered in the appropriate Control?

To me your post sounds as if it's the latter case, but you can use this code to do either.

In frmApplication:

Private Sub Go2AppSpeciesForm_Click()

If Not IsNull(Me.AppID) Then
  DoCmd.OpenForm "frmAppSpecies", , , , , , Me.AppID
 Else
  MsgBox "An AppID Must Be Entered First!"
 End If

End Sub

In frmAppSpecies:

Private Sub Form_Load()

Dim rst As Recordset

If Not IsNull(Me.OpenArgs) Then
 Set rst = Me.RecordsetClone
 
 rst.FindFirst "[AppID] = " & Me.OpenArgs 
 
   If Not rst.NoMatch Then
      Me.Bookmark = rst.Bookmark
   Else
    DoCmd.GoToRecord , , acNewRec
    Me.AppID = Me.OpenArgs
  End If

rst.Close
Set rst = Nothing

End If

End Sub

The above code assumes that AppID is Numeric. If it is actually defined Text, replace the line

rst.FindFirst "[AppID] = " & Me.OpenArgs

with

rst.FindFirst "[AppID] = '" & Me.OpenArgs & "'"

You'll also need to replace Go2AppSpeciesForm with the actual name of your Command Button.

Linq ;0)>

[jfn15]

Yes, the ID field is numeric, and your code works perfectly! Thank you!

[Missinglinq]

Glad we could help!

Linq ;0)>