Login form not working properly

[papa yaw]

The login form says access denied to everything entered even if the data entered correspondings with the data in the table. The complete code is shown below.

Option Compare Database
Option Explicit
Private Sub Login_Click()
Static count As Integer
'Verify if data is entered in the username box
If IsNull(Me.EmployeeId) Or Me.EmployeeId = "" Then
MsgBox "Please enter a username.", vbOKOnly, "Required Data"
Me.EmployeeId.SetFocus
Exit Sub
End If
'Verify if data is entered in the password box
If IsNull(Me.Password) Or Me.Password = "" Then
MsgBox "Please enter a Password.", vbOKOnly, "Required Data"
Me.Password.SetFocus
Exit Sub
End If
EmployeeId = Nz(DLookup("strEmployeeid", "tblEmployee", "StrEmployeeId='" & Me.EmployeeId & "'"), "")
Password = Nz(DLookup("strPassword", "tblEmployee", "StrPassword='" & Me.Password & "'"), "")
If Me.EmployeeId = "strEmployeeId" And Me.Password = "strPassword" Then
MsgBox "Access Granted", vbInformation, "Logging in....."


DoCmd.Close
DoCmd.OpenForm "Menu"
Else
MsgBox "Access Denied"
count = count + 1
If count = 3 Then
MsgBox "You have failed to login on three tries", vbCritical, "Exiting...."
DoCmd.CloseDatabase
End If
End If
End Sub

[amrut]

check your code for the words in red :

EmployeeId = Nz(DLookup("strEmployeeid", "tblEmployee", "StrEmployeeId='" & Me.EmployeeId & "'"), "")
Password = Nz(DLookup("strPassword", "tblEmployee", "StrPassword='" & Me.Password & "'"), "")
If Me.EmployeeId = "strEmployeeId" And Me.Password = "strPassword" Then
Are the field names and variables correct ? Should it be If Me.EmployeeId = EmployeeId And Me.Password = Password Then

[Missinglinq]

These lines

EmployeeId = Nz(DLookup("strEmployeeid", "tblEmployee", "StrEmployeeId='" & Me.EmployeeId & "'"), "")
Password = Nz(DLookup("strPassword", "tblEmployee", "StrPassword='" & Me.Password & "'"), "")

really make no sense to me! It appears that you're using Variables (EmployeeID and Password) that have the same names as Controls on your Form, and after that I simply have no idea!

At any rate, I ran up a db with your Field and Control names, and the following accomplishes all of your stated goals:

Private Sub Login_Click()

Static count As Integer

'Verify if data is entered in the username box
If IsNull(Me.EmployeeID) Or Me.EmployeeID = "" Then
 MsgBox "Please enter a username.", vbOKOnly, "Required Data"
 Me.EmployeeID.SetFocus
 Exit Sub
End If

'Verify if data is entered in the password box
If IsNull(Me.Password) Or Me.Password = "" Then
 MsgBox "Please enter a Password.", vbOKOnly, "Required Data"
 Me.Password.SetFocus
 Exit Sub
End If

If DCount("*", "tblEmployee", "strEmployeeId & strPassword = '" & Me.EmployeeID & Me.Password & "'") > 0 Then

 MsgBox "Access Granted", vbInformation, "Logging in....."
 DoCmd.Close
 DoCmd.OpenForm "Menu"

Else

 MsgBox "Access Denied"
 count = count + 1
 If count = 3 Then
  MsgBox "You have failed to login on three tries", vbCritical, "Exiting...."
 DoCmd.CloseDatabase

End If

End If
End Sub

Linq ;0)>