Run-time error '2501' The OpenReport action was canceled

[cowboy]

I have a way to open a report, but if there is no data current when I open the report it gives me a run time error and crashes.



The code I am using to call

Private Sub cmbPrintManhole_Click()
    Dim str1 As String
    If Me.cmbArea = "ALL" Then
        DoCmd.OpenReport "PEC_StormDrainManholeReport", acViewPreview, , "[Manhole Number (12)] <> """""
    Else
        str1 = Me.cmbArea
        DoCmd.OpenReport "PEC_StormDrainManholeReport", acViewPreview, , "[Area] ='" & str1 & "'"
    End If
End Sub

Under the report that is being called I have the "On No Data" Property set to the following code:

Private Sub Report_NoData(Cancel As Integer)
    MsgBox "No records in current selection"
    Cancel = True
End Sub

When I click the button to Open the report in print view it brings up a message box like it is suppose to then after I click OK it brings up a Run-time error'2501': The OpenReport action was canceled.

Any help would be appreciated, thank you.

[RuralGuy]

It looks right. I would start by *importing* your db into a fresh, new db and see if the problem follows. http://www.btabdevelopment.com/ts/impnew

[cowboy]

I imported it to a fresh file and the problem was still there. :-(

[RuralGuy]

Hmm...is your ac2003 fully patched including the HotFixes? If you comment out the MsgBox but leave the Cancel = True does it still give you the RunTime error?

[cowboy]

I forgot to update my version, I am using Access 2010. I commented out the msgbox and got the same error.

[RuralGuy]

You have error handling code in your cmbPrintManhole button don't you? Canceling the report causes the 2501 error.

[RuralGuy]

Did I lose you there?

[cowboy]

Sorry I was busy with something else for a second, but I dont have code under the cmbPrintManhole button for error handling, is there a place on the properties or something that error handling can be held? I am not very familiar with error handling.

[RuralGuy]

Do you have any code in the OnError event of your form?

[cowboy]

I have nothing under the On Error property on my form which has the button or the report that is being opened.

[RuralGuy]

Let's go the other way. The default for ac2010 is "Break on Unhandled Errors". Let's add error handling to the procedure. Replace what you have with:

Private Sub cmbPrintManhole_Click()
   On Error GoTo Err_cmbPrintManhole_Click
   Dim stDocName As String
   stDocName = "PEC_StormDrainManholeReport"
   If Me.cmbArea = "ALL" Then
      DoCmd.OpenReport stDocName, acViewPreview, , "[Manhole Number (12)] <> ''"
   Else
      DoCmd.OpenReport stDocName, acViewPreview, , "[Area] ='" & Me.cmbArea & "'"
   End If
Exit_cmbPrintManhole_Click:
   Exit Sub
Err_cmbPrintManhole_Click:
   If Err <> 2501 Then
      MsgBox "Error Number: " & Err.Number & vbCrLf & _
             "Description:  " & Err.Description
   End If
   Resume Exit_cmbPrintManhole_Click
End Sub

[cowboy]

Well that worked, thank you very much. I will go back and look at what is actually going on to learn for next time.

[RuralGuy]

It took that second cup of coffee this morning to get my brain started.

[cowboy]

So after looking back at what the code does, it looks like we just let the error occur but when error 2501 occurs just we tell the program what to do instead of crash. Does that sound right?

[RuralGuy]

Exactly right! By canceling the ReportOpen, we in effect have created the 2501 error which is passed back to the OpenReport procedure and needs to be handled by that procedure. In this case we will display all *but * the 2501 error.