Import Excel to Access

[kilo21]

Hello experts and beginners alike,



I'm planning for the creation of a button in a form. It will display browse window, when clicked, and allows you to select an Excel workbook. In the same window, a "Save" button allows you to import the Excel into new table in Access.

----

(Here's my progress. I still need your help!)

I put the following code inside the button's VBA editor in Access:

Private Sub cmdFileOpenBrowse_Click()
'   Browse for open file
    
    Dim myOpenFileName As Variant
    myOpenFileName = GetOpenFileEnd Sub

Then I put the following code found into a new module known as Module1.

Option Compare Database

'This code was originally written by Ken Getz.
'It is not to be altered or distributed,
'except as part of an application.
'You are free to use it in any application,
'provided the copyright notice is left unchanged.
'
' Code courtesy of:
'   Microsoft Access 95 How-To
' Ken Getz and Paul Litwin
' Waite Group Press, 1996

Type tagOPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    strFilter As String
    strCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    strFile As String
    nMaxFile As Long
    strFileTitle As String
    nMaxFileTitle As Long
    strInitialDir As String
    strTitle As String
    Flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    strDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
    Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
    Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000


Function RecallFileLocation() As String
    Dim strFilter As String, strLoc As String
    Dim lngFlags As Long, MyDefault As String
    strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mda, *.mdb)", _
                    "*.MDA;*.MDB")
    'strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)", "*.DBF")
    strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)", "*.TXT")
    strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.xls)", "*.XLS")
    strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")

    MyDefault = FindDefaults("DefaultOpenLocation")
    ' MsgBox ValidateLocations(MyDefault)   Returns results of test to see if exists
      
    RecallFileLocation = ahtCommonFileOpenSave(InitialDir:=MyDefault, _
        Filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
        DialogTitle:="Find File to Open!")
    
    '    MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="S:\Assignment List\", _
    '    Filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
    '    DialogTitle:="Find File to Open!")
    ' Since you passed in a variable for lngFlags,
    ' the function places the output flags value in the variable.
    Debug.Print Hex(lngFlags)
End Function

Function GetOpenFile(Optional varDirectory As Variant, _
    Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
    lngFlags = ahtOFN_FILEMUSTEXIST Or _
                ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
    If IsMissing(varDirectory) Then
        varDirectory = ""
    End If
    If IsMissing(varTitleForDialog) Then
        varTitleForDialog = ""
    End If

    ' Define the filter string and allocate space in the "c"
    ' string Duplicate this line with changes as necessary for
    ' more file templates.
    strFilter = ahtAddFilterItem(strFilter, _
                "Access (*.mdb)", "*.MDB;*.MDA")
    ' Now actually call to get the file name.
    varFileName = ahtCommonFileOpenSave( _
                    OpenFile:=False, _
                    InitialDir:=varDirectory, _
                    Filter:=strFilter, _
                    Flags:=lngFlags, _
                    DialogTitle:=varTitleForDialog)
    MsgBox varFileName
    If Not IsNull(varFileName) Then
        varFileName = TrimNull(varFileName)
    End If
    GetOpenFile = varFileName
End Function

Function ahtCommonFileOpenSave( _
            Optional ByRef Flags As Variant, _
            Optional ByVal InitialDir As Variant, _
            Optional ByVal Filter As Variant, _
            Optional ByVal FilterIndex As Variant, _
            Optional ByVal DefaultExt As Variant, _
            Optional ByVal FileName As Variant, _
            Optional ByVal DialogTitle As Variant, _
            Optional ByVal hwnd As Variant, _
            Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
    ' Give the dialog a caption title.
    If IsMissing(InitialDir) Then InitialDir = CurDir
    If IsMissing(Filter) Then Filter = ""
    If IsMissing(FilterIndex) Then FilterIndex = 1
    If IsMissing(Flags) Then Flags = 0&
    If IsMissing(DefaultExt) Then DefaultExt = ""
    If IsMissing(FileName) Then FileName = ""
    If IsMissing(DialogTitle) Then DialogTitle = ""
    If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
    If IsMissing(OpenFile) Then OpenFile = True
    ' Allocate string space for the returned strings.
    strFileName = Left(FileName & String(256, 0), 256)
    strFileTitle = String(256, 0)
    ' Set up the data structure before you call the function
    With OFN
        .lStructSize = Len(OFN)
        .hwndOwner = hwnd
        .strFilter = Filter
        .nFilterIndex = FilterIndex
        .strFile = strFileName
        .nMaxFile = Len(strFileName)
        .strFileTitle = strFileTitle
        .nMaxFileTitle = Len(strFileTitle)
        .strTitle = DialogTitle
        .Flags = Flags
        .strDefExt = DefaultExt
        .strInitialDir = InitialDir
        ' Didn't think most people would want to deal with
        ' these options.
        .hInstance = 0
        '.strCustomFilter = ""
        '.nMaxCustFilter = 0
        .lpfnHook = 0
        'New for NT 4.0
        .strCustomFilter = String(255, 0)
        .nMaxCustFilter = 255
    End With
    ' This will pass the desired data structure to the
    ' Windows API, which will in turn it uses to display
    ' the Open/Save As Dialog.
    If OpenFile Then
        fResult = aht_apiGetOpenFileName(OFN)
    Else
        fResult = aht_apiGetSaveFileName(OFN)
    End If

    ' The function call filled in the strFileTitle member
    ' of the structure. You'll have to write special code
    ' to retrieve that if you're interested.
    If fResult Then
        ' You might care to check the Flags member of the
        ' structure to get information about the chosen file.
        ' In this example, if you bothered to pass in a
        ' value for Flags, we'll fill it in with the outgoing
        ' Flags value.
        If Not IsMissing(Flags) Then Flags = OFN.Flags
        ahtCommonFileOpenSave = TrimNull(OFN.strFile)
    Else
        ahtCommonFileOpenSave = vbNullString
    End If
End Function

Function ahtAddFilterItem(strFilter As String, _
    strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.

    If IsMissing(varItem) Then varItem = "*.*"
    ahtAddFilterItem = strFilter & _
                strDescription & vbNullChar & _
                varItem & vbNullChar
End Function

Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
    intPos = InStr(strItem, vbNullChar)
    If intPos > 0 Then
        TrimNull = Left(strItem, intPos - 1)
    Else
        TrimNull = strItem
    End If
End Function

The button worked. The browse menu appeared. I was able to select an Excel file in any directory. However, the import operation did not happen for some reason after clicking "Save". Nothing was imported into Access.

Is there fault in the code? How to provoke Access to import the Excel after selecting it in this particular browse window? I also appreciate thread suggestions with similar context and solution. Thanks.

Note:-
Code shown found at http://www.mrexcel.com/forum/showthread.php?t=82469

[ssanfu]

All of the code you posted was just to open the File Open/Save dialog box so you could pick a file name.

However, you still have to write code to do the import - whether it is to use the TransferSpreadsheet method or open the Excel workbook and read the data cell by cell.

[kilo21]

Thank goodness ssanfu for the reply. Now I know why. So I'm missing the import component..

Ok, I think I have the TransferSpreadsheet code below:

Private Sub Command0_Click()
On Error GoTo Err_CmdImportExcel_Click
DoCmd.TransferSpreadsheet transfertype:=acImport, tablename:="Hours Worked", FileName:="C:/Personnel/Hours Worked.xls", HasFieldNames:=True
Exit_CmdImportExcel_Click:
Exit Sub
Err_CmdImportExcel_Click:
MsgBox Err.Description
Resume Exit_CmdImportExcel_Click

End Sub

I've experimented with the code above. It only works when importing Excel from a fixed directory path stated in the code. For example, "C:/Personnel/Hours Worked.xls".

If I want to combine the TransferSpreadsheet with the aforementioned Open/Save functionality (so I can browse the directories and then import), where do I put this TransferSpreadsheet code?

[ssanfu]

This is how I would code it:

Private Sub Command0_Click()
   On Error GoTo Err_CmdImportExcel_Click

   Dim myOpenFileName As String
   Dim strFilter As String

   '-----------------------------------------------------
   'Open the OpenFile Dialog box to get the Excel filename
   '-----------------------------------------------------
   strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.xls)", "*.XLS")
   strFilter = ahtAddFilterItem(strFilter, "CSV Text Files (*.csv)", "*.CSV")
   strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")
   'get the file name
   myOpenFileName = ahtCommonFileOpenSave( _
                    Filter:=strFilter, OpenFile:=True, _
                    DialogTitle:="Please select an input file...", _
                    Flags:=ahtOFN_HIDEREADONLY)

   'check for a file name
   If Len(Trim(myOpenFileName)) > 0 Then
      DoCmd.TransferSpreadsheet transfertype:=acImport, tablename:="Hours Worked", FileName:= myOpenFileName, HasFieldNames:=True
   Else
      MsgBox "No file name selected" & vbNewLine & vbNewLine & "Aborting Import!!!!!"
   End If

Exit_CmdImportExcel_Click:
   Exit Sub
Err_CmdImportExcel_Click:
   MsgBox Err.Description
   Resume Exit_CmdImportExcel_Click

End Sub

This is the actual entry point into the code to get the file name: "ahtCommonFileOpenSave". You don't need the function "GetOpenFile". It was an example.....

BTW, It is really not a good idea to use spaces in object names: "Hours Worked"

[kilo21]

It works. So far, brilliant ssanfu!

Finally to make things more flexible, which line of code do I need to change or add, if I am to import a different worksheet in the Excel workbook?

Please, because I notice it always imports the first sheet regardless if there is any data in the second or third sheet. This constraint is devastating to me

[ssanfu]

I don't import from Excel any more. But here is a site with many examples on how to import (and export) from Excel workbooks with many sheets.

http://www.accessmvp.com/kdsnell/EXCEL_MainPage.htm

[kilo21]

I've viewed the link and I think it will be very helpful to me. You're awesome!

I'll try to work my way from here. But thank you, for all the help you've given.

See you around. Plus, have a nice day.