VBA Help Requested

[aamer]

Hi,

i need help with the following vba code. I have no knowledge on VBA.


Private Sub Command49_Click()
On Error GoTo Err_Handler

Const REPORTNAME = "Cheque Book Detail"
Const MESSAGETEXT = "Both a Cheque Paid To and Account Catagory must be selected."
Dim strCriteria As String

' build string expression to filter report
' to selected Cheque Paid To and Account Catagory
strCriteria = "[ChqIssuedWorker] = """ & Me.issu2 & """"
" And [ChqTypePmt] = """ & Me.AccountCatagory & """"

' make sure a Cheque Paid To is selected
If Not IsNull(Me.issu2) And Not IsNull(Me.AccountCatagory) Then
' open report filtered to selected Cheque Paid To
DoCmd.OpenReport REPORTNAME, _
View:=acViewPreview, _
WhereCondition:=strCriteria
Else
MsgBox MESSAGETEXT, vbExclamation, "Invalid operation"
End If

Exit_Here:
Exit Sub

Err_Handler:
MsgBox Err.Description, vbExclamation, "Error"
Resume Exit_Here
End Sub



The problem is in the following line
" And [ChqTypePmt] = """ & Me.AccountCatagory & """"


and I have no clue how to fix this.

[June7]

Where did you get the code from?

What is the problem - are you getting an error message, what is the message?

[ssanfu]

Try:

strCriteria = "[ChqIssuedWorker] = """ & Me.issu2 & """"
strCriteria = strCriteria & " And [ChqTypePmt] = """ & Me.AccountCatagory & """"

[RayMilhon]

Another way is to use the line continuation & _ at then end.

strCriteria = "[ChqIssuedWorker] = """ & Me.issu2 & """" & _
" And [ChqTypePmt] = """ & Me.AccountCatagory & """"

[aamer]

Thank you Ray Milhon
Both of the following are working great, can you tell me what is different about them.


strCriteria = "[ChqIssuedWorker] = """ & Me.issu2 & """"
strCriteria = strCriteria & " And [ChqTypePmt] = """ & Me.AccountCatagory & """"

And

strCriteria = "[ChqIssuedWorker] = """ & Me.issu2 & """" & _
" And [ChqTypePmt] = """ & Me.AccountCatagory & """"


Thank you once again.

[June7]

The first syntax builds up the complete criteria string in steps by concatenation with the variable. Useful for debugging very long code lines.

The second is really one long statement that is continued on multiple lines. The underscore (_) is VBA line continuation character. It means 'read the following line as continution of this line'. Just makes code easier to read without having to scroll horizontally to read a complete line.

[RayMilhon]

June7 explains it very well.

[aamer]

thx June & Ray