Opening Form to Specific Record Issue

[Ganymede]

I'm attempting to use a DoCmd.OpenForm code to open a form to a specific record. However, the form that I'm attempting to open has an On Open event that automatically puts the form to a new record when opened.

DoCmd.GoToRecord acDataForm, Me.Name, acNewRec

As a result, the DoCmd.OpenForm doesn't work properly. Basically, the form goes to a new record instead of the specific record I want it to go to.

I could fix this problem by removing the OnOpen event. But I have that OnOpen event there for a reason. Most of the time, when users are opening this form, they are looking to add a new record. I have the OnOpen event to save them the trouble of hitting "add record." But occasionally the user will be opening this form to access a specific record. That is why I'm trying to write this DoCmd.OpenForm code.

Any ideas what I can do to work around this problem?

[orange]

See this for info re DoCmd.OpenForm method

and this youtube video

Review your logic. Make sure what you are using(Access-wise) addresses the issue you are trying to resolve.

Don't overlook google to help you find info.

[Missinglinq]

Don't know how, exactly, you're currently telling the secondary Form which Record to go to, but if you use the OpenArgs parameter of the OpenForm command to do this

DoCmd.OpenForm "SecondaryFormName", , , , , , Me.RecordID

you can then check, in the secondary Form, to see if OpenArgs is populated, or not. If it is populated, you go to the appropriate Record; if it isn't populated, you go to a New Record.

Notice that I use the Form_Load event, rather than the Form_Open event; this is always preferable when dealing with Record data, as the data is often not available in the Form_Open event.

Private Sub Form_Load()

Dim rst As DAO.Recordset

If Not IsNull(Me.OpenArgs) Then
 
 Set rst = Me.RecordsetClone
 
 rst.FindFirst "[RecordID] = '" & Me.OpenArgs & "'"
 'rst.FindFirst "[RecordID] = " & Me.OpenArgs ' Use this for a Numeric ID
  
  If Not rst.NoMatch Then
      Me.Bookmark = rst.Bookmark
   Else
    DoCmd.GoToRecord , , acNewRec
   End If

rst.Close

Set rst = Nothing

End If

End Sub

The rst.FindFirst "[RecordID] line in black is the correct syntax if the unique identifying Field is Text.

If the unique identifying Field (RecordID, in the example) is Numeric, you'd use the line in red, instead.

Linq ;0)>