FileCopy - I can Browse and select a file... How can I tell it where to save

[nono5551212]

Hello,

I am creating a button... when clicked it will pull up the Windows File Browser.... and let the user select a file.

This part I can do. My problem is that I need it to save to a directory I set (It will be the same directory every time)

How can i get it to save with the original file name to this directory \\server\share

Say a user... Clicks the button.... points to a file c:\test.txt.. when he clicks ok.... how can I get it to save to \\server\share\test.txt... (The file name will be different every time... Path will be the same)

Private Sub btUploadDoc_Click()
    'First, let the user select the file
    Dim sourcePath As String
    Dim fd As Office.FileDialog
    Set fd = Application.FileDialog(MsoFileDialogType.msoFileDialogFilePicker)
    With fd
        .Title = "Please select file to upload"
        ' Show the dialog and retrieve the final path selected by the user
        .Filters.Clear
        .Filters.Add "All Files", "*.*"
        .AllowMultiSelect = False
        If .Show = True Then
            sourcePath = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    Set fd = Nothing
    
    'Now, do the upload and save the details in the Document table
    FileCopy sourcePath, DestPath
End Sub

I need to make this line

 FileCopy sourcePath, DestPath

Take the source file... keeping source name... prefix it with \\server\share...

so basically when users upload files it will look like
\\server\share\Test.pdf
\\server\share\Notes.docx

[ranman256]

You have to start with a full server path because it won't work using drive letters.

then Capture the path
I= instrRev(sourcepath,"\")
sDir = left(sourcepath,I)

[nono5551212]

I don't follow. I must admit I do not know VB at all. Where would your code fit into my code?

In my mind, and my total lack of VB knowledge... I was hoping for it to look like something I could understand. Like my Example below.


BELOW IS NOT REAL CODE

Dim sourcePath as String
Dim destPath as String


destPath = "\\server\share"


FileCopy sourcePath, destPath + sourceFilename

[nono5551212]

I got this help from a different site... It works...

I was hoping someone could show me how to add a message box that would say "File Already Exists" if the file already existed..
and not copy anything if the file already existed

Private Sub Command0_Click()
    Const msoFileDialogFilePicker As Long = 3
    Const DestinationFolder As String = "\\kratos\share\new\"
    Dim fd As Object 'Office.FileDialog
    Dim DestinationPath As String
    Dim sourcePath As String

    Set fd = Application.FileDialog(msoFileDialogFilePicker)
    With fd
        .Title = "Please select file to upload"
        .Filters.Clear
        .Filters.Add "All Files", "*.*"
        .AllowMultiSelect = False
        If .Show = True Then
            sourcePath = .SelectedItems(1)
        End If
    End With
    Set fd = Nothing
    If Len(sourcePath) > 0 Then
        DestinationPath = DestinationFolder & Dir(sourcePath)
        Debug.Print DestinationPath '<- inspect this in Immediate window; Ctrl+g will take you there
        FileCopy sourcePath, DestinationPath
    End If
End Sub

[CJ_London]

use the dir function before the filecopy to check if the file already exists

see this link on the dir function

https://msdn.microsoft.com/en-us/lib.../gg278779.aspx