Use vba to detect if excel is open.

[redbull]

Hello, I am wondering if there is a way to determine of a user has an open version of excel running. I have people who are opening a .xls file from the internet. These files are being OPENED NOT SAVED to their local machines. So I wonder if I can just figure out if excel is running, then interact with it from there...

[ssanfu]

Check out this site:
http://www.accessmvp.com/kdsnell/EXC...m#WriteRstFile

Look for this comment in the code
' Establish an EXCEL application object

The code below it checks if Excel is open...

[orange]

Here is a routine I found a few years back that may help. I've included a test routine (and I started excel and tested it just now) and it resulted in True. I'm using Ac2010, but have used this with 2003.

'---------------------------------------------------------------------------------------
' Procedure : IsExeRunning
' Author    :  James Barash(AccessD)
' Created   : 3/17/2009
' Purpose   : To determine if a specific program is currently running.
'---------------------------------------------------------------------------------------
' Last Modified:
'
' Inputs:  The name of the program
' Dependency: N/A
'------------------------------------------------------------------------------
'
Public Function IsExeRunning(strExeName As String) As Boolean
Dim objProcesses As Object, objProcess As Object
  IsExeRunning = False
  Set objProcesses = GetObject("winmgmts://" & Environ$("ComputerName") _
 & "/root/cimv2").ExecQuery("select * from Win32_Process")
  If Not objProcesses Is Nothing Then
    For Each objProcess In objProcesses
      If objProcess.name = strExeName Then
          IsExeRunning = True
          Exit For
      End If
    Next
    Set objProcess = Nothing
    Set objProcesses = Nothing
  End If
End Function

'---------------------------------------------------------------------------------------
' Procedure : jtestit
' Author    : Jack
' Created   : 3/17/2009
' Purpose   : Test routine to ensure IsEXERunning function is working
'---------------------------------------------------------------------------------------
' Last Modified:
'
' Inputs: N/A
' Dependency: N/A
'------------------------------------------------------------------------------
'
Sub jtestit()
Dim smyEXE As String

'smyEXE = "msaccess.exe"
smyEXE = "excel.exe"
Debug.Print "Is " & smyEXE & " running: " & IsExeRunning(smyEXE)
End Sub

Debug.print output
Is excel.exe running: True