Importing DVLA API data into table

[Welshgasman]

https://developer-portal.driver-vehi...-ves-api-guide

Cheers.

[Edgar]

Any idea why it's not compatible with version 2007? This is the code:

Option Compare Database
Option Explicit

Private Sub btnRequest_Click()

    If IsNull(Me.RegistrationNumber) Then
        MsgBox "Missing registration number"
        Exit Sub
    End If

    Dim strUrl As String
    Dim strApiKey As String
    Dim objRequest As Object
    Dim objReqBody As Object
    Dim strResponse As String
    
    'use a dictionary to avoid string manipulation
    Set objReqBody = CreateObject("Scripting.Dictionary")
    objReqBody.Add "registrationNumber", Me.RegistrationNumber

    'assign your variables
    strUrl = "https://driver-vehicle-licensing.api.gov.uk/vehicle-enquiry/v1/vehicles"
    strApiKey = "XXX"
    
    'instantiate http
    Set objRequest = CreateObject("MSXML2.XMLHTTP")

    'send http request
    With objRequest
        .Open "POST", strUrl, False
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "Accept", "application/json"
        .setRequestHeader "x-api-key", strApiKey
        
        'convert dictionary to JSON
        .send JsonConverter.ConvertToJson(objReqBody)
        
        'store response in a string variable
        strResponse = .responseText
        
        'visualize response in immediate window
        Debug.Print strResponse
    End With

    'convert string response to a dictionary
    Dim parsedResponse As Object
    Set parsedResponse = JsonConverter.ParseJson(strResponse)
    
    If parsedResponse("message") = "Forbidden" Then
        MsgBox "Bad api key"
    Else
        'populate your textboxes
        Me.txtMake = parsedResponse("make")
        Me.txtColour = parsedResponse("colour")
        Me.txtEngineCapacity = parsedResponse("engineCapacity")
        Me.txtFuelType = parsedResponse("fuelType")
        Me.txtYearOfManufacture = parsedResponse("yearOfManufacture")
        Me.txtFirstRegistered = parsedResponse("monthOfFirstRegistration")
        Me.txtmotStatus = parsedResponse("motStatus")
        Me.txtmotDueDate = parsedResponse("motExpiryDate")
        Me.txtTaxStatus = parsedResponse("taxStatus")
        Me.txtTaxDueDate = parsedResponse("taxDueDate")
        Me.txtDateLastV5Issued = parsedResponse("dateOfLastV5CIssued")
    End If
    
End Sub

[Welshgasman]

Says I need 14, I am on 12.
I have managed to get into the code now and copy and paste to a new db.
I also have 2 keys would you believe from the DVLA.

[Edgar]

I'm glad you made it work, too bad I don't have that version to debug the issues.

[Welshgasman]

Oh I do not have it working yet.
I was unable to import the form to a new DB. I am going to recreate it later.