Default file location File Picker

[davedinger]

I have been working on a very simple Document Management sytem for a while now and along time ago I was given this code that allows me to click on a form button that opens the Diaogue File Picker, (Thanks for all of your help and Ideas by the way everone, your help is greatly appreciated!) When the file picker opens it then allows a User to select a document and stores the location in a field named Location. it works great!!!


The issue I am having now is that people cant always find the doccument location so they cant store the locations. Not to mention I have people storing documents everyplace Arrrg. By default the File Picker goes to the users MY Documents Folder and the users cant fgure out how to navigate to the right Network Folder. I would like to set our scanner to scan documents to a specific network folder and then have the file picker open to that Folder by default so that it will reduce issues.
I've researched this and played with .InitialFileName = "C:\Windows\DocumentStorage" but i cant figure out where it goes in the code.
Can You Help?


- - - - - - - - - - - - -

Private Sub Command26_Click()
Dim objFD As Object
Dim strOut As String


strOut = vbNullString
'msoFileDialogFilePicker = 3
Set objFD = Application.FileDialog(3)
If objFD.Show = -1 Then
strOut = objFD.SelectedItems(1)
End If
Set objFD = Nothing
FolderSelection = strOut


Dim strChoice As String
strChoice = FolderSelection
If Len(strChoice) > 0 Then
Me.Location = strChoice


Else
' what should happen if user cancelled selection?
End If

End Sub

---------------------

[moke123]

difficult to read your code without formatting and code tags so I'll just post what I use and I think you'll be able to see where it goes.

Function fBrowse(PickType As MsoFileDialogType, Optional StartFolder As String = "", Optional strTitle As String = "") As String

    On Error GoTo fBrowse_Error

    Dim mso As Object
    Dim varFile As Variant

    If Nz(strTitle, "") = "" Then

        Select Case PickType

        Case 3
            strTitle = "Select a File"
        Case 4
            strTitle = "Select a Folder"
        Case Else
            strTitle = ""

        End Select

    Else

        strTitle = strTitle

    End If

    Set mso = Application.FileDialog(PickType)

    With mso

        .Title = strTitle
        .AllowMultiSelect = False
        .InitialFileName = StartFolder
        .Filters.Clear

If PickType = msoFileDialogFilePicker Then
        
        .Filters.Add "All Files", "*.*"
        .Filters.Add "PDF file", "*.pdf"
        .Filters.Add "Image Files", "*.jpg,*.jpeg,*.BMP,*.Png,*.TIFF,"
        .Filters.Add "Audio Files", "*.Wav,*.mp4"

End If
        
        If .Show = True Then

            If .SelectedItems.Count = 0 Then

                fBrowse = ""

            End If

            For Each varFile In .SelectedItems

                fBrowse = varFile

            Next

        Else

            fBrowse = ""

        End If

    End With

On Error GoTo 0

    Exit Function

fBrowse_Error:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure fBrowse, line " & Erl & "."

End Function

Btw, suggest you write a public function to handle this kind of procedure, or use mine or any other you can find.
Then in the button click on your form you only need

Me.Location = fBrowse(msoFileDialogFilePicker, "C:\Windows\DocumentStorage")

[Micron]

Lookup msoFileDialogFilePicker to see all of its properties and nuances. What you want is called .InitialFileName. Your code could test that the returned path or part of it matches what you want it to be. And yes, please do use code tags (# button on posting toolbar) to maintain indentation and readability.

[davedinger]

Sorry I didnt know about the Code Icon. Let me try the code again. As I said before this works great but it just defaults to the wrong Folder. I hope I'm using the Code Tag below correctly.

Private Sub Command26_Click()
Dim objFD As Object
Dim strOut As String


strOut = vbNullString
'msoFileDialogFilePicker = 3
Set objFD = Application.FileDialog(3)
If objFD.Show = -1 Then
strOut = objFD.SelectedItems(1)
End If
Set objFD = Nothing
FolderSelection = strOut


Dim strChoice As String
strChoice = FolderSelection
If Len(strChoice) > 0 Then
Me.Location = strChoice
Else
' what should happen if user cancelled selection?
End If

End Sub

[Welshgasman]

I have google on my laptop.
https://www.google.com/search?q=msoF...hrome&ie=UTF-8

[Micron]

Thank you for choosing to implement code tags - close, but no indentation, which is a big help.
I don't think you followed my suggestion to research the dialog or you'd know what you need?

Playing with your code I have drafted the following as a starting point (and it shows how indentation should look)

Private Sub Command26_Click() 'should give your controls meaningful names
Dim objFD As Object
Dim strOut As String

'msoFileDialogFilePicker = 3
Set objFD = Application.FileDialog(3)
With objFD
 'set dialog properties here, like 
   .InitialFileName = ??
   MultiSelect = ??
   .etc ??
End With

If objFD.Show Then
   'do stuff such as
   strOut = objFD.SelectedItems(1) 'this returns path of selected file
   'do more stuff?
Else
   Exit Sub 'no point in continuing if user chose Cancel
End If

' no point in testing if user chose a file because if you have already exited, they didn't

Set objFD = Nothing

End Sub

Also no need to pass selection data from one variable to another (strChoice = FolderSelection) so I eliminated that situation.

[davedinger]

Thats that ticket! Thanks Micron. Your comments in the code helped allot. I can see how the code works now
I also added a line that sent the selection to a field on my form named "Location"

The final code is below. Thanks again.

Private Sub Command26_Click()

   Dim objFD As Object
Dim strOut As String


'msoFileDialogFilePicker = 3
Set objFD = Application.FileDialog(3)
With objFD
 'set dialog properties here, like
   .InitialFileName = "C:\Users\Dave\Desktop\Hawaii Photos\Hawaii David"
 
End With


If objFD.Show Then
   'do stuff such as
   strOut = objFD.SelectedItems(1) 'this returns path of selected file
   Me.Location = strOut 'This Sends the file selection to the Field named Location
   
Else
   Exit Sub 'no point in continuing if user chose Cancel
End If


' no point in testing if user chose a file because if you have already exited, they didn't


Set objFD = Nothing


End Sub

[Micron]

Glad to help and know that you got something working. But I think I'd eliminate some of the comments I interjected as information for you.