Select only fields with checked checkbox

[smasak]

Good morning. In this sample, I have a "chkAll" checkbox and a "checkS" checkbox next to each record. When I check "chkAll" checks all entries and click copybutton(which has the code) copies all fields with selPh in txtCOPY.
What I want is to check the checkS checkbox in each record and copies only those records.
For example check test2 and test3(checkbox "checkS") and only those 2 selPh fields copy.

Thank you

[ranman256]

Run an append query,(not a copy)
unless you are copying to paste into excel. If so, run an export.
no need to 'copy'.

[mike60smart]

Hi
Seeing as I don't read Russian it is difficult to help

[smasak]

Thank you for your answer ranman256. The problem is that append the cell phones(field selPh) on different rows not the same saperated by comma.

[accesstos]

Hi Sakis!

Give a try to this code for the "Copy Button":
(I have commented the unnecessary/wrong lines)

Private Sub copyF_Click()
    Dim rst As Object
    Dim strTemp As String

    'strTemp = vbNullString
    'If Nz(Form_STUDENTS.chkAll, False) Then
    'Set rst = Form_STUDENTS.RecordsetClone 'Wrong object reference!

    Set rst = Me!STUDENTS.Form.RecordsetClone
    With rst
        If Not .BOF Then .MoveFirst
        While Not .EOF
            If !CheckS Then
                strTemp = strTemp & .Fields("SelPh") & ","
            End If
            .MoveNext
        Wend
    End With
    'End If

    Me.txtCOPY = Null
    If Len(strTemp) > 0 Then
        Me.txtCOPY = Left(strTemp, Len(strTemp) - 1)
    End If
    If Not rst Is Nothing Then Set rst = Nothing
End Sub

Also I suggest this simpler condition for the WHERE clause of the recordsource of the form STUDENTS:

WHERE (((STUDENTS.Ενεργός)=[Forms]![frmCOPY]![STUDENTS]![ChkFilter] Or (STUDENTS.Ενεργός)=-1))

I hope it helps and welcome to accessforums!
John

Edit:
But there is a better practice: You can move the whole functionality in the STUDENTS form as a Build-In, Read-Only property, making with this way much simpler the outer procedures.
Add this Property Get method in the code module of the STUDENTS form:

Property Get Phones() As Variant
    Dim varTemp As Variant
    
    varTemp = Null
    With Me.RecordsetClone
        If Not .BOF Then .MoveFirst
        While Not .EOF
            If !CheckS Then
                varTemp = varTemp & ("," + .Fields("SelPh"))
            End If
            .MoveNext
        Wend
    End With
    Phones = Mid(varTemp, 2)
End Property

Then, you have only one line of code to add in click event of the copy button (and any other procedure):

Private Sub copyF_Click()
    Me.txtCOPY = Me!STUDENTS.Form.Phones
End Sub

[smasak]

Perfect, both solutions work perfectly. Thank you very much.
I wish you and everyone in the forum happy new year.

[smasak]

Good morning, if i want it the phone numbers not separated by comma but as if a line change is being made(as you see at image) then how will the code be configured?
Property Get Phones() As Variant
Dim varTemp As Variant

varTemp = Null
With Me.RecordsetClone
If Not .BOF Then .MoveFirst
While Not .EOF
If !CheckS Then
varTemp = varTemp & ("," + .Fields("SelPh"))
End If
.MoveNext
Wend
End With
Phones = Mid(varTemp, 2)
End Property

[smasak]

I change the code like this
" varTemp = varTemp & ("30" + .Fields("selPh") + vbNewLine) "
but cuts the first digit of the first number from the set...
The "30" is the prefix of country.

[CJ_London]

because of this - the original code

varTemp = varTemp & ("," + .Fields("SelPh"))

the new code

varTemp = varTemp & ("30" + .Fields("selPh") + vbNewLine)

you are adding the new line to the end, not the beginning so when this bit of code runs

Phones = Mid(varTemp, 2)

you are chopping off the first character, which was a , and now is 3

[smasak]

I change the code like this
" varTemp = varTemp & ("30" + .Fields("selPh") + vbNewLine) "
but cuts the first number from the set...
The "30" is the prefix of country.

[accesstos]

I change the code like this
" varTemp = varTemp & ("30" + .Fields("selPh") + vbNewLine) "
but cuts the first number from the set...
The "30" is the prefix of country.

As Ajax said, you have to replace the comma with vbNewLine, which has two characters length, so, you have to start from the third character for the output.

'[...]
varTemp = varTemp & (vbNewLine + "30" + .Fields("selPh"))
'[...]
Phones = Mid(varTemp, 3)
End Property

Edit:
But, maybe you want to change the Property Get method with a function with an optional argument for the separator.That will give more control to outer procedures:

(in STUDENTS form)

Function Phones(Optional strSep As String = vbNewLine) As Variant
    Dim varTemp As Variant
    
    varTemp = Null
    With Me.RecordsetClone
        If Not .BOF Then .MoveFirst
        While Not .EOF
            If !CheckS Then
                varTemp = varTemp & (strSep + "30" + .Fields("selPh"))
            End If
            .MoveNext
        Wend
    End With
    Phones = Mid(varTemp, Len(strSep) + 1)
End Function

(in frmCopy form)

Private Sub copyF_Click()
    Me.txtCOPY = Me!STUDENTS.Form.Phones
    'Me.lstPhones.RowSource = Me!STUDENTS.Form.Phones(";")  'Rowsource for a listbox
    'Me.lblPhones.Caption = Me!STUDENTS.Form.Phones(" ")    'Caption for a label
End Sub

[smasak]

Once again thank you very much.

[accesstos]

You are very welcome!