Runtime error 3075

[Thompyt]

I error out on the red bold : qthisQuery.sql = strPassedSQL" as


Syntax error (missing operater) in query expression '([FrmTitle])=CCB Open Change Requests'.

I am pretty sure I am srewing the pooch on this part:
WHERE ([FrmTitle])=" & TempVars!TempFormTitle & "

Sub BoardSel(arg)
    Dim sSQL1 As String
    Select Case arg
        Case 1
            sSQL1 = "SELECT IIf([AOVote]='Approve' And [ActionComplete]=False And [Level]<>'Level 1','CCB Open Change Requests', 'In Progress Change Requests') AS FrmTitle, " _
            & "tblChangeRequest.CRID, qryLookup.CRNumbers, qrySwitching.Levels, qrySwitching.DateIDs, qrySwitching.Status, tblChangeRequest.ChangeType, " _
            & "qrySwitching.HBVers, qrySwitching.Units, qrySwitching.MTOEParas, qrySwitching.People, tblChangeRequest.ChangeRequested, tblChangeRequest.Rationale, " _
            & "tblChangeRequest.NOTES, tblChangeRequest.ActionItems, tblChangeRequest.ActionComplete, tblChangeRequest.NIE, qrySwitching.DaysOpen, qrySwitching.Levelz, " _
            & "tblChangeRequest.AOVote, qrySwitching.CRLevel, tblChangeRequest.Change, IIf([FinalVote]<>'','     Date Closed: ' & Format([DateClosed],'Long Date'),Null) AS DClosed " _
            & "FROM (tblChangeRequest INNER JOIN qryLookup ON tblChangeRequest.CRID = qryLookup.CRID) INNER JOIN qrySwitching ON tblChangeRequest.CRID = qrySwitching.CRID " _
            & "WHERE ([FrmTitle])=" & TempVars!TempFormTitle & ";"

            Call fcnCustomizeSQL("qRecSrcChanges", sSQL1)
    End Select
End Sub
Function fcnCustomizeSQL(qName As String, strPassedSQL As String) As Boolean
    
Dim qthisQuery As DAO.QueryDef
    
    If TempVars!tvEnableErrorHandling = True Then On Error GoTo fcnCustomizeSQL_Error   'if the query has been deleted, create it
    If DCount("Name", "MSysObjects", "[Name] = " & Chr$(39) & qName & Chr$(39)) = 0 Then
        Set qthisQuery = CurrentDb.CreateQueryDef(qName, strPassedSQL)
        Set qthisQuery = Nothing
        Exit Function
    End If

    Set qthisQuery = CurrentDb.QueryDefs(qName)
    qthisQuery.sql = strPassedSQL
fcnCustomizeSQL_Exit:
    On Error Resume Next
    Set qthisQuery = Nothing
    Exit Function
fcnCustomizeSQL_Error:
    MsgBox Err.Number & ", " & Err.Description & ", fcnCustomizeSQL"
    Resume fcnCustomizeSQL_Exit
End Function

[Thompyt]

Fixed it:

WHERE ([FrmTitle])='" & TempVars!TempFormTitle & "'

[June7]

Try adding apostrophe string delimiters:


& "WHERE ([FrmTitle])='" & TempVars!TempFormTitle & "';"

EDIT: and now I see you solved it.