User Login Form remains Opened at backend!

[cap.zadi]

I am using this code for user loging but user form remains opened at back end.

How this form can be closed automatically after successful login.

Private Sub cmdOk_Click()On Error GoTo Err_cmdOk_Click
'-----------------------------------------------------------------------------------------------------------------------------
' This code is used to validate users found in the tblSecurity table. If the wrong user name or password is
' provided access is denied.
' Created by: Liam Sullivan
' Date Created: 08 Jan 2012
' Date Modified: 08 Jan 2012
'-----------------------------------------------------------------------------------------------------------------------------
    Dim db As DAO.Database
    Dim rst As DAO.Recordset
    Dim rstV As Recordset
    Dim stDocName As String
    Dim stLinkCriteria As String
    
    Set db = CurrentDb()
    Set rst = db.OpenRecordset("tblSecurity", dbOpenDynaset)
    
    If Not IsNull(Me.txtUser) And Not IsNull(Me.txtPassword) Then
        rst.FindFirst "Password = '" & Me.txtPassword & "'" & " And UserID = '" & Me.txtUser & "'"
    
        If rst.NoMatch Then
            MsgBox "You entered an incorrect Username or Password." & Chr(13) & _
            "Please enter the correct Username and Password or " & Chr(13) & _
            "contact the Administrator for assistance.", vbOKOnly + vbCritical, "Logon Denied"
        ElseIf Me.txtPassword = "password" Then
            MsgBox "This is the first time you've logged in or your password has been reset." & Chr(13) & _
            "You must change your password before you can log in.", _
            vbOKOnly + vbExclamation, "Change Password"
            stDocName = "frmUserLogonNew"
            stLinkCriteria = "[UserID]=" & "'" & Me![txtUser] & "'"
            DoCmd.OpenForm stDocName, , , stLinkCriteria
        Else
            stDocName = "Mainmenu"
            DoCmd.OpenForm stDocName, , , stLinkCriteria
        End If
    Else
        MsgBox "You have left the Username and/or Password blank." & Chr(13) & _
        "Please enter the correct Username and Password or " & Chr(13) & _
        "contact the Adminstrator for assistance.", vbOKOnly + vbCritical, "Logon Denied"
    End If
    
    With User
        .AccessID = rst.Fields("AccessID")
        .ViewID = rst.Fields("ViewID")
        .Active = rst.Fields("Active")
        .Password = rst.Fields("Password")
        .SecurityID = rst.Fields("SecurityID")
        .UserID = rst.Fields("UserID")
    End With
    
    rst.Close
    
Exit_cmdOk_Click:
    Exit Sub


Err_cmdOk_Click:
    MsgBox Err.Description
    Resume Exit_cmdOk_Click


End Sub

[June7]

Why is login form in backend?

Review https://msdn.microsoft.com/VBA/Acces...-method-access

[cap.zadi]

Sorry, for not clear text. At back-end means at the backside of the other forms while working after login.

Thanks for the example code.

How it can be closed automatically after successful login?

[davegri]

I'd try this:

Exit_cmdOk_Click:
    docmd.close acform, me.name
    Exit Sub

[cap.zadi]

Dear

Thanks for the help

It is working.

Exit_cmdOk_Click:
docmd.close acform, me.name
Exit Sub

[cap.zadi]

Hi

I regret to inform you late which observed just now that the login form even will be closed and database remains opened if clicked on "Login" button even "no password" or "wrong password" entered.

Kindly advise.

[davegri]

Add the red code:

    Dim db As DAO.Database    
    Dim rst As DAO.Recordset
    Dim rstV As Recordset
    Dim stDocName As String
    Dim stLinkCriteria As String
    
If len(me.txtPassword & vbnullstring) = 0 then
    msgbox "Password cannot be blank!"
    exit sub
end if

If len(me.txtUser & vbnullstring) = 0 then
    msgbox "User cannot be blank!"
    exit sub
end if
 
Set db = CurrentDb()
    Set rst = db.OpenRecordset("tblSecurity", dbOpenDynaset)
If Not IsNull(Me.txtUser) And Not IsNull(Me.txtPassword) Then
        rst.FindFirst "Password = '" & Me.txtPassword & "'" & " And UserID = '" & Me.txtUser & "'"
    
        If rst.NoMatch Then
            MsgBox "You entered an incorrect Username or Password." & Chr(13) & _
            "Please enter the correct Username and Password or " & Chr(13) & _
            "contact the Administrator for assistance.", vbOKOnly + vbCritical, "Logon Denied"
        ElseIf Me.txtPassword = "password" Then

Or maybe this would be easier than the above:

       Else
            stDocName = "Mainmenu"
            DoCmd.OpenForm stDocName, , , stLinkCriteria
        End If
    Else
        MsgBox "You have left the Username and/or Password blank." & Chr(13) & _
        "Please enter the correct Username and Password or " & Chr(13) & _
        "contact the Adminstrator for assistance.", vbOKOnly + vbCritical, "Logon Denied"
        exit sub
    End If

[cap.zadi]

Dear

Thanks for the feedback.

the only remaining part is now, it can be closed even on entering wrong password but cant be on null.

any further advise?

[davegri]

Re-read the original problem. Close the login form when appropriate.
Go back to the original code and add the red lines. They will close the login form after opening the new form.
Move the blue lines. They have to be executed before the form_Onclose event

        If rst.NoMatch Then
            MsgBox "You entered an incorrect Username or Password." & Chr(13) & _
            "Please enter the correct Username and Password or " & Chr(13) & _
            "contact the Administrator for assistance.", vbOKOnly + vbCritical, "Logon Denied"
        ElseIf Me.txtPassword = "password" Then
            MsgBox "This is the first time you've logged in or your password has been reset." & Chr(13) & _
            "You must change your password before you can log in.", _
            vbOKOnly + vbExclamation, "Change Password"
            stDocName = "frmUserLogonNew"
            stLinkCriteria = "[UserID]=" & "'" & Me![txtUser] & "'"
            DoCmd.OpenForm stDocName, , , stLinkCriteria
            Set rst = Nothing
            DoCmd.close acform, Me.Name
        Else
             With User
                 .AccessID = rst.Fields("AccessID")
                 .ViewID = rst.Fields("ViewID")
                 .Active = rst.Fields("Active")
                 .Password = rst.Fields("Password")
                 .SecurityID = rst.Fields("SecurityID")
                 .UserID = rst.Fields("UserID")            
             End With
             Set rst = nothing    
             stDocName = "Mainmenu"
             DoCmd.OpenForm stDocName, , , stLinkCriteria
             DoCmd.close acForm, Me.Name
        End If
    Else
        MsgBox "You have left the Username and/or Password blank." & Chr(13) & _

[cap.zadi]

Sir

Its working fantastic now.

Thanks for ur help.