I downloaded your database. There are 51 queries.
I have made a small report showing the query names and the query SQL. The report is attached.
Here is the routine that produced the report.
You can adjust the file name to reflect your directory.
You can insert the ListQueries subroutine into a new module in your database, and run it when/as necessary.
Code:
'---------------------------------------------------------------------------------------
' Procedure : ListQueries
' Author : mellon
' Date : 11-Aug-2016
' Purpose : Routine to list all queries in this database. It will print the query name
' and the SQL of the query to a file. You can change the name of the file to reflect your
' own info.
'---------------------------------------------------------------------------------------
'
Sub ListQueries()
Dim qdf As DAO.QueryDef
Dim icnt As Integer
Dim sTitleOfReport As String
Dim QList As String
'This is the default location where queries will be written.
' eg C:\users\yourUserName\ListQueries11_Aug_2016_08_14_40.txt
10 On Error GoTo ListQueries_Error
20 QList = "C:\users\mellon\documents\ListQueries" & Format(Now, "DD_MMM_YYYY_HH_NN_SS") & ".txt"
'This is the default name of the Query List Report
30 sTitleOfReport = " List of Current Queries "
40 Open QList For Output As #1
50
60 Print #1, " " & sTitleOfReport & " Date:" & Now()
70 Print #1, " "
80 Print #1, " " & "Associated file is " & QList
90 Print #1, " "
100 For Each qdf In CurrentDb.QueryDefs
110 If Not Left(qdf.Name, 1) = "~" Then
120 Debug.Print qdf.Name & vbCrLf & vbTab & qdf.SQL
130 Print #1, "QUERY NAME: " & qdf.Name & vbCrLf & "---------------------------"
140 Print #1, vbCrLf & vbCrLf & vbTab & qdf.SQL
150 icnt = icnt + 1
160 End If
170 Next qdf
180 Debug.Print "Total number of queries is " & icnt
190 Print #1, "Total number of queries is " & icnt
200 Close #1
210 On Error GoTo 0
220 Exit Sub
ListQueries_Error:
230 MsgBox "Error " & Err.Number & " in line " & Erl & " (" & Err.Description & ") in procedure ListQueries of Module Mellon_Jack"
End Sub
When you open your database, be sure to hold down the shift key in order to see your queries.
For online training --search youtube videos for 599CD (Richard Rost) he has a multi-part intro series that starts here.
There are several free youtube videos that should be useful.
Good luck.