Run time error 13 "type mismatch"

[CHEECO]

Me again. I found the below file and it works great,however when you click on one of the date boxes with out choosing a departmentand employee you get the run time error. I would like to eliminate the run timeerror and have it replaced with a message box that says you must choose adepartment and employee.

This is the code that is giving the error

Function SendToInputBox(mynum)
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim f As Form
    Dim g As String
    Dim MyDate As Date
    Dim UName As String
    
    Set db = CurrentDb()
    Set rs = db.OpenRecordset("tblInput",dbOpenDynaset)
    Set f = Forms!frmCalendar

MyDate = Format(f("Date" & mynum),"mm/dd/yyyy")
    UName = f.cboUser.Column(1)
    g = Format(MyDate, "dddd mmmm d, yyyy")
    
    rs.FindFirst "InputDate = #" & MyDate &"# AND UserID = " & glngUserID
    
    DoCmd.OpenForm "frmInputBox"
    With Forms!frmInputBox
    
    If Not rs.NoMatch Then
           !txtAttendanceReason = rs!AttendanceReason
            !InputText =rs!InputText
            
    End If
        !InputDay = mynum
        !InputDate = MyDate
        !InputFor = g
        !NameLabel1.Caption = UName:
        !original_text =f.Controls("Text" & mynum)
        !InputText =f.Controls("Text" & mynum)
        !InputText.SetFocus
        End With
    
    SendKeys "{F2}^{HOME}", False
End Function

It is the line in red that is highlighted yellow when I get the error The belowis the file it self. I also must say it is very well done. Just has the aboveclitch.

[nrgins]

Without knowing more about what this code is or what it does or where department and employee are or what they are, I can only answer in general.

To prevent the error if Department and Employee aren't completed, you can simply put at the top your routine:

If IsNull(f.Department) Or IsNull(f.Employee) Then Exit Function

Change "Department" and "Employee" to whatever the names of the controls actually are.

[CHEECO]

The code open a form named "input Box". This form allows the user to choose from a list why the employee has that day off and input a comment. It only works if the user chooses an department and employee first. If not that error pops up. The user does not no why the error has popped up, that is why I would like to change it to a message box saying you must choose an department and employee. Another option would be have a default department and employee automatically inserted when the calendar is opened so the error does not occur.

[davegri]

    Set db = CurrentDb()
    Set rs = db.OpenRecordset("tblInput", dbOpenDynaset)
    Set f = Forms!frmCalendar
    
    If Len(f.cboDepartment.Column(1) & vbNullString) = 0 Then
        MsgBox "You must select a department and employee"
        Exit Function
    End If
    If Len(f.cboUser.Column(1) & vbNullString) = 0 Then
        MsgBox "You must select a department and employee"
        Exit Function
    Else
        UName = f.cboUser.Column(1)
    End If
    MyDate = Format(f("Date" & mynum), "mm/dd/yyyy")
    g = Format(MyDate, "dddd mmmm d, yyyy")

Add the above code changes to function SendToInputBox.

[CHEECO]

That worked perfect. Thank-you very much.

[davegri]

Glad to help. Good luck with that project!

[nrgins]

The code open a form named "input Box".

OK, then put what I wrote in the line before the code opens a form called "input box." If you want to include a message, then change it to this:

If IsNull(f.Department) Or IsNull(f.Employee) Then 
    MsgBox "You must first enter a department and an employee.", vbinformation
    Exit Function
End If