VBA Coding Help please

[cfobare79]

I have this code below that I have put together. I don't know much about coding but need to ensure Text boxes are filled out and if they are filled out then close window and open form "LogIn". Currently the text boxes are verified but if they are not complete I get my message box which you hit ok on and it just opens up the "LogIn" page without allowing you to finish filling out the current form "Customer Form".

Private Sub ShoppingCart_Click()
Dim msg As String, Style As Integer, Title As String
Dim nl As String, ctl As Control




nl = vbNewLine & vbNewLine


For Each ctl In Me.Controls
If ctl.ControlType = acTextBox Then
If ctl.Tag = "*" And Trim(ctl & "") = "" Then
msg = "Data Required for '" & ctl.Name & "' field!" & nl & _
"You can't save this record until this data is provided!" & nl & _
"Enter the data and try again . . . "
Style = vbCritical + vbOKOnly
Title = "Required Data..."


MsgBox msg, Style, Title
ctl.SetFocus
Cancel = True
DoCmd.BrowseTo acBrowseToForm, "LogIn"
Exit For

End If
Else

End If

Next

End Sub

[June7]

Cancel = True means nothing in the Click event. This is a feature of BeforeUpdate event. Need an Else branch

If ... Then
'msgbox code
Else
DoCmd.BrowseTo acBrowseToForm, "LogIn"
End If

I've never used BrowseTo, only OpenForm. Is this a web db?

[cfobare79]

This is not a web db. The BrowseTo function does both the open new window and close current window functions as one code. I have been doing a lot of research but I am still very new to code so I'm not sure exactly how to implement your comment above. Can you explain in a little more detail the "If...Then 'msgbox code" part?

[June7]

I was being lazy and not replicating your code - modify your code as suggested. I just noticed the Else branch in your code, move it above the BrowseTo line. The Exit For and Cancel are not needed.

[cfobare79]

With the code below nothing is happening and the "End Sub" is highlighted yellow. I really have little to no clue what I'm doing so the more detail the better.


Private Sub ShoppingCart_Click()
Dim msg As String, Style As Integer, Title As String
Dim nl As String, ctl As Control




nl = vbNewLine & vbNewLine


For Each ctl In Me.Controls
If ctl.ControlType = acTextBox Then
If ctl.Tag = "*" And Trim(ctl & "") = "" Then
msg = "Data Required for '" & ctl.Name & "' field!" & nl & _
"You can't save this record until this data is provided!" & nl & _
"Enter the data and try again . . . "
Style = vbCritical + vbOKOnly
Title = "Required Data..."
MsgBox msg, Style, Title
ctl.SetFocus
Cancel = True
Else
DoCmd.BrowseTo acBrowseToForm, "LogIn"
End If
Else


End If

Next

End Sub

[June7]

Sorry, I was wrong about the Exit For, it is useful. Also, think you need a Boolean and the Else actually is not needed.

Dim booContinue As Boolean
booContinue = True
For Each ctl In Me.Controls
     If ctl.ControlType = acTextBox Then
        If ctl.Tag = "*" And Trim(ctl & "") = "" Then
               msg = "Data Required for '" & ctl.Name & "' field!" & nl & _
               "You can't save this record until this data is provided!" & nl & _
                       "Enter the data and try again . . . "
               Style = vbCritical + vbOKOnly
               Title = "Required Data..."
               MsgBox msg, Style, Title
               ctl.SetFocus
               booContinue = False
               Exit For
         End If
     End If
Next
If booContinue Then DoCmd.BrowseTo acBrowseToForm, "LogIn"
 End Sub

[cfobare79]

You are wonderful... I can't thank you enough for taking time out of your Sunday to fix my code.