calculate no. of working days

[JOSE LUIS]

First of all I´m sorry for my English. I´m an a rockie in access and I´m like to question the forum about how I can create a date function than calculate the amount of working days between dates (startdate and endate) after take into account the banking holidays that are previously introduced in a table. I don´t Know if this is the best way to do it.
> Best regards


> JOSE LUIS

[RuralGuy]

Here's what I use and YES I create a holiday table.

Public Function WorkingDays(StartDate As Date, EndDate As Date) As Integer
'-- Return the number of WorkingDays between StartDate and EndDate
    On Error GoTo err_workingDays
    Dim intCount As Integer
    If IsDate(StartDate) And IsDate(EndDate) Then
        If EndDate >= StartDate Then
            intCount = 0
            Do While StartDate < EndDate
                StartDate = StartDate + 1
                If Weekday(StartDate, vbMonday) <= 5 Then
                    '-- Use the following code if you have a "Holiday" table
                    '         If Weekday(StartDate, vbMonday) <= 5 And _
                              IsNull(DLookup("[Holiday]", "tblHolidays", _
                              "[HolDate] = " & Format(StartDate, "\#mm\/dd\/yyyy\#;;;\N\u\l\l"))) Then
                    intCount = intCount + 1
                End If
            Loop
            WorkingDays = intCount
        Else
            WorkingDays = -1    '-- To show an error
        End If
    Else
        WorkingDays = -1    '-- To show an error
    End If
exit_workingDays:
    Exit Function
err_workingDays:
    MsgBox "Error No:    " & Err.Number & vbCr & _
           "Description: " & Err.Description
    Resume exit_workingDays
End Function