writing to text file (array set)

[pradeep.sands]

Hi guys,
I need some help. Consider I have a table, something like this:




Now I need to write a code from a form, in vba, to a text file such that my text file has this:

{ab1,cd1,ef1,gh1}
{ab2,cd2,ef2,gh2}
{ab3,cd3,ef3,gh3}

I am guessing, maybe I read number of records and columns from table (opened as recordset) and store them in two integer variables..
introws = .recordcount
intcolumns = .fields.count

and now I move to first record (.movefirst), and then write all the columns of that record into {.......}
and then move to next record and write all the columns of that record into a new {.....}
and so on till .eof is reached..

will this work???
I have this idea, but I m unable to write the code to implement this....can someone help?
if there is another easy way, you are welcome to help me

[TG_W]

Have you tried DoCmd.OutputTo to a text file (acFormatTXT)?

[pradeep.sands]

Actually the table is a filtered table...I mean to say I filtered the actual table and opened as a record set.
and now I will have to write data from this recordset (filtered table) and Not from the actual/original table

[TG_W]

What about writing the recordset to a temporary table then outputting from there? You could have a delete SQL to clear the temp table at the start of the operation.

EDIT

[pradeep.sands]

Ya I can do that. But, if I use DoCmd.outputto then my output file doesnt look the way I want it to..
I want my txt file to look exactly like this:

{ab1,cd1,ef1,gh1}
{ab2,cd2,ef2,gh2}
{ab3,cd3,ef3,gh3}

When I use DoCmd.outputto then my output txt file also looks like the table (with all borders/boxes shown)

[ssanfu]

Try this:
(NOTE: requires a reference to DAO)

Public Sub Export2Txt()
   Dim r As DAO.Recordset
   Dim k As Integer
   Dim sSQL As String
   Dim tmpString As String
   Dim path As String

   'open the text file
   k = FreeFile
   '  Change the text file name to whatever you want
   Open "Output.txt" For Output As #k

   'open the recordset
   'Change the SQL to your SQL
   sSQL = "SELECT [Field1], [Field2], [Field3], [Field4]  FROM [YourTable]"
   Set r = CurrentDb.OpenRecordset(sSQL)

   ' or if you have a saved query, use
   '   Set r = CurrentDb.OpenRecordset("YourFilteredQueryName")

   If Not r.BOF And Not r.EOF Then
      r.MoveLast
      r.MoveFirst

      'loop through the recordset
      Do While Not r.EOF
         tmpString = ""
         tmpString = "{" & r.Fields(0) & "," & r.Fields(1) & "," & r.Fields(2) & "," & r.Fields(3) & "}"
         Print #k, tmpString
         r.MoveNext
      Loop
   End If

   'clean up
   Close #k
   r.Close
   Set r = Nothing

   'just to let you know when it is over!!  :-)
   MsgBox "done"
End Sub