If combo box is certain answer then make another field required

[AussieGal]

Hi,

I have a combo box (OsubAbuse) on a form that allows uses to select Yes, no or unknown (1, 2 or 3). I want it so that if they select yes (2) in the combo, the next field ODignosis is required to have something entered into it and not left blank.

I have a botton on the form they must press to get the report they need to print, but I already have code in there, so I am not sure how the new code would fit in there although it seems that this would be the best place to put it.
Below is the existing code on the button (which as well as beeps, brings up a message box for other fields that are required which is called from another module)

Option Compare Database
Option Explicit
Private Sub cmdPrintEpisodeForm_Click()
If validateform(Me) Then
    DoCmd.RunCommand acCmdSaveRecord
    DoCmd.Minimize
    DoCmd.OpenReport "rptEpisodeSummaryPrintable", acViewPreview, , "EpisodeID = " & Me.EpisodeID
Else: DoCmd.Beep
End If
End Sub

Hoping someone can help. Thanks in advance

[June7]

Something like:

If Me.OsubAbuse = 2 And IsNull(Me.ODiagnosis) Then
MsgBox "Must enter diagnosis."
ElseIf validateform(Me) Then
...

Is validateform a custom function? The Me reference might error. Try: Me.Name

[AussieGal]

This works great. Thank you. I knew it was something simple. ValidateForm is a custom function I have not had any issues yet. What it does is checks that all required fields on the form are compelete.
I have pasted it for reference:

Option Compare Database
Public Function validateform(myform As Form) As Boolean
'returns true if all required fields have data, or false if not.
'It will also create a popup message explaining which fields need data
Dim boolresponse As Boolean
Dim strError As Variant
Dim ctl As Control
boolresponse = True
strError = Null
With myform
    For Each ctl In .Controls
      With ctl
        If .Tag = "required" Then
           If .Value & "" = "" Then
                boolresponse = False
                strError = (strError + ", ") & .Name
            End If
        End If
      End With
    Next ctl
End With
If strError & "" <> "" Then MsgBox "The following information must be entered first: " & strError, vbInformation
validateform = boolresponse
End Function

Thanks so much for your response.