Carrying request ID and Customer Info into a new frm from existing frm using a button

[asmith533]

I have a database that collects customer requests and customer feedback among other information. The issue I have is that not every request has feedback and not every feedback is the result of a request, therefore requiring the two seperate tables. I've created two forms, one for requests (Frm_CustomerRequest) and one for feedback (Frm_CustomerFeedbackCR). I'm not the best at programming and I need some help on how to carry the customer information and the request ID over into the feedback form from the request form by clicking the "Add Feedback" button. I've attached the database structure in a zip file.

[June7]

You have an embedded macro for the button code, I use only VBA. I don't know if macros can accomplish what I suggest.

I would use the OpenArgs argument of OpenForm to pass info to the Feedback form and then have the Feedback form grab data from the open Request form.

Sub Feedback_Click()
DoCmd.RunCommand acCmdSaveRecord
DoCmd.OpenForm "Frm_CustomerFeedbackCR", acNormal, "", "", acFormAdd, acNormal, "Request"
End Sub

Then in Current event of Feedback form:

Private Sub Form_Current()
If Me.OpenArgs = "Request" Then
Me.TblFeedback_Request_ID = Form_Frm_CustomerRequest.TblRequest_ID
Me.TblFeedback_Customer_ID = Form_Frm_CustomerRequest.TblRequest_Customer_ID
End If
End Sub

Or you can even pass the ID info in the OpenArgs and parse them:

DoCmd.OpenForm "Frm_CustomerFeedbackCR", acNormal, "", "", acFormAdd, acNormal, Me.TblRequest_ID & ":" & Me.TblRequest_Customer_ID

Private Sub Form_Current()
If Len(Me.OpenArgs) > 0 Then
Me.TblFeedback_Request_ID = Left(Me.OpenArgs, InStr(Me.OpenArgs,":")-1)
Me.TblFeedback_Customer_ID = Mid(Me.OpenArgs, InStr(Me.OpenArgs,":")+1)
End If
End Sub

[asmith533]

That worked perfectly! Thanks!!!