Send object as PDF with caption name

[Flytkjaer]

Hi i'm looking for a soloution where i can get an E-mail botton to send an e-mail with a unique named pdf file attached.



Here is my VBA for the calling button.

Private Sub E_Mail_Ordre_Click()
On Error GoTo Err_Send_bestilling_Click
        Dim stDocName As String
    
    DoCmd.SendObject _
    acSendReport, _
    "Sparepart_Return_Order", _
    acFormatPDF, _
    "E@Mail.here", _
    , _
    , _
    "Sparepart order No: " & [Ordre_Hoved_Id], _
    "Messages body.", _
    False
 
Exit_Send_bestilling_Click:
    Exit Sub
Err_Send_bestilling_Click:
    MsgBox Err.Description
    Resume Exit_Send_bestilling_Click
    
End Sub

Here is my VBA for the report which i would like to be attached to the mail.

Private Sub Report_Activate()
Me.Caption = "Return Of Spareparts No:" & [Forms]![Retur_Ordre_Hoved]![Ordre_Hoved_Id]
End Sub

When i hit the e-mail button, Access process my request and send out the mail, allthough i would have to allow the outgoing mail from access. but the problem is that the attached pdf file are named after report name not the title.
I would like to end up with an attachment named something like this: Sparepart_Order_No_x.pdf

Thanks for your assistance in advanvce.

[June7]

Google: Access VBA email report as pdf

I don't think SendObject gives option to name the attachment. I use this method for email: http://forums.aspfree.com/microsoft-...ro-447084.html

Might have to save the report as a pdf first, see
http://www.access-programmers.co.uk/...d.php?t=141517
http://database.ittoolbox.com/groups...a-code-1463260
http://www.granite.ab.ca/access/emai...ttachments.htm

[Flytkjaer]

Hi June7

Maybe your right, but would it be possible to pass the title along to the report in any otherway, and how is it done?

I think the problem in my initial project, is that the report never opens during this operation.

[June7]

The only 'other way' I know of is to save the report to PDF with name of your preference in one action and then attach the saved PDF to email in another action. The referenced links have code samples.

[Flytkjaer]

Hi June7

For those of you who would like Access to sendout an e-mail with an attached pdf file, where the file has been given as unique name. Here is how to do it!
This code opens the report, renames it and export it to you mail client. Press the send button and the mail is send and the report closes.

There wouldl be promted for send or if you change
DoCmd.SendObject acSendReport, stReport, "PDFFormat(*.pdf)", stEmail, , , stSubject, stEmailMessage, True,
To False
You will be promted for Allow or Disallow security warning.

Private Sub E_Mail_Ordre_Click()
On Error GoTo Err_Send_bestilling_Click
    Dim stReport As String
    Dim stWhere As String
    Dim stEmail As String
    Dim stSubject As String
    Dim stEmailMessage As String
    Dim ReportCap As String
    
    stEmailMessage = "Message goes here." & vbCrLf & vbCrLf & "Best Regards" & vbCrLf & "Sender."   'E-mail body
    stSubject = "Subject goes here: " & [Ordre_Hoved_Id] 'Email Subject
    stReport = "Sparepart_Return_Order" 'Original name of the Report
    ReportCap = "Spare parts return"    'Current Report Caption
    stEmail = "e-mail@e-mail.xx"    'E-mail adresses or (Me.E-mail fieldname)
    DoCmd.OpenReport stReport, acViewPreview, "", stWhere, acWindowNormal, ""   'Opens the report
    Reports!Sparepart_Return_Order.Caption = "Output filename:" & [Ordre_Hoved_Id]    'Renames the Report
    DoCmd.SendObject acSendReport, stReport, "PDFFormat(*.pdf)", stEmail, , , stSubject, stEmailMessage, True, "" 'Send out the E-mail
    DoCmd.Close acReport, stReport, acSaveNo
       
    
    
Exit_Send_bestilling_Click:
    Exit Sub
Err_Send_bestilling_Click:
    MsgBox Err.Description
    Resume Exit_Send_bestilling_Click
    
End Sub

[June7]

Congratulations! Ingenious! Glad you figured out a solution.

[Flytkjaer]

Hmm. i wonder why i left this in my code.

Dim stWhere As String

And

DoCmd.OpenReport stReport, acViewPreview, "", stWhere, acWindowNormal, "" 'Opens the report