Hide Access 2010 runtime window

[cevatyildiz]

Hello,

My all forms are popup and runs in windowless with help of following codes in normal Access 2007 but whenever I try to run my project in Access 2010 runtime, it shows the background window. Can you give me a solution to hide background Access window?

 
Option Compare Database
Option Explicit
'Arka ekranı gizleme
Public Declare Function CreateRectRgn Lib "gdi32" (ByVal X1 As Long, _
ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Public Declare Function CreateRoundRectRgn Lib "gdi32" (ByVal X1 As Long, _
ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long, ByVal X3 As Long, _
ByVal Y3 As Long) As Long
Declare Function CombineRgn Lib "gdi32" (ByVal hDestRgn As Long, _
ByVal hSrcRgn1 As Long, ByVal hSrcRgn2 As Long, _
ByVal nCombineMode As Long) As Long
Public Declare Function SetWindowRgn Lib "user32" (ByVal hWnd As Long, _
ByVal hRgn As Long, ByVal bRedraw As Boolean) As Long
Public Const RGN_AND = 1
Public Const RGN_COPY = 5
Public Const RGN_DIFF = 4
Public Const RGN_OR = 2
Public Const RGN_XOR = 3
 
Public Function degistir1()
Dim rgn1 As Long, rgn2 As Long
 
rgn1 = CreateRectRgn(0, 0, 1, 1)
CombineRgn rgn1, rgn1, rgn2, RGN_OR
SetWindowRgn Application.hWndAccessApp, rgn1, True
End Function
 
Form_Load()
Call degistir1
End sub

[RuralGuy]

Did you intend to mark this thread as Solved? If so, care to share your solution with others that read this Forum?

[cevatyildiz]

Yes, I found and used another code block rather than this one. It works very well...

Option Compare Database
Option Explicit
Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3
Private Declare Function apiShowWindow Lib "user32" _
                                       Alias "ShowWindow" (ByVal hWnd As Long, _
                                                           ByVal nCmdShow As Long) As Long
                                                           
Function fSetAccessWindow(nCmdShow As Long)
   Dim loX As Long
   Dim loform As Form
   On Error Resume Next
   Set loform = Screen.ActiveForm
   If Err <> 0 Then
      loX = apiShowWindow(hWndAccessApp, nCmdShow)
      Err.Clear
   End If
   If nCmdShow = SW_SHOWMINIMIZED And loform.Modal = True Then
      MsgBox "Cannot minimize Access with " _
             & (loform.Caption + " ") _
             & "form on screen"
   ElseIf nCmdShow = SW_HIDE And loform.PopUp <> True Then
      MsgBox "Cannot hide Access with " _
             & (loform.Caption + " ") _
             & "form on screen"
   Else
      loX = apiShowWindow(hWndAccessApp, nCmdShow)
   End If
   fSetAccessWindow = (loX <> 0)
End Function

Hope it works for anyone he will need

[RuralGuy]

Thanks for sharing.

[cevatyildiz]

it's a pleasure