Error Message

[Juan4412]

I have a combo box that will search through the records in my table, and if the search item is located it will display the record. If the search item is not found, I get the following error:



The following runtime error occurred:
Number: 94
Description: Invalid use of Null
Object Type: Form
Procedure: Combo48_AfterUpdate
Object: frm_111
Contact the application administrator


Can someone tell me how to make this error not display, and just display "not found" or something like that or "not in the database" whatever the default message is. I tried recreating my form, and i still get the error.

[pbaldy]

What's the code behind the combo?

[Juan4412]

Code Behind Cbo Box

   Private Sub Combo48_AfterUpdate()  
On Error GoTo Err_Combo48_AfterUpdate 
       ' Find the record that matches the control.  
    Dim rs As Object 
       Set rs = Me.Recordset.Clone  
    rs.FindFirst "[id] = " & Str(Me![Combo48])  
    Me.Bookmark = rs.Bookmark 
   Exit_Combo48_AfterUpdate:  
    Exit Sub 
   Err_Combo48_AfterUpdate:  
    Select Case Err.Number  
    Case 0  
        Resume Next  
    Case Else  
        Call gsErrorHandler(Err, Application.CurrentObjectName, Application.CurrentObjectType, "Combo48_AfterUpdate")  
    End Select 
       Resume Exit_Combo48_AfterUpdate 
    
   End Sub

[ssanfu]

You are not checking the NoMatch property after doing a FindFirst. Try this:

Private Sub Combo48_AfterUpdate()
   On Error GoTo Err_Combo48_AfterUpdate
   ' Find the record that matches the control.
   Dim rs As Object
   Set rs = Me.Recordset.Clone
   rs.FindFirst "[id] = " & Str(Me![Combo48])
   'check to see if record found
   If rs.NoMatch Then
      MsgBox "No record matched"
   Else
      Me.Bookmark = rs.Bookmark
   End If

Exit_Combo48_AfterUpdate:
   Set rs = Nothing
   Exit Sub
Err_Combo48_AfterUpdate:
   Select Case Err.Number
      Case 0
         Resume Next
      Case Else
         Call gsErrorHandler(Err, Application.CurrentObjectName, Application.CurrentObjectType, "Combo48_AfterUpdate")
   End Select
   Resume Exit_Combo48_AfterUpdate

End Sub

[Juan4412]

Adding those lines of code, causes the error message to go away. Thanks!!!

My next question pertaining to this is, when the search item is not located, it is displaying a message that says,
"
The text you entered isn’t an item in the list.

Select an item from the lsit, or enter text that matches one of the listed items."

Is there a way for me to change the message that is displayed?

[ssanfu]

It sounds like the limit to list property is set to YES. Change it to NO.

Read about the "Limit To List" property in Help.

You could change the combo box to a text box and add a button with the search code. You wouldn't get the error message, but you would have to type in the data you want to search for.