Forms! syntax

[GraeagleBill]

I'm trying to find why my referenced to the forms collection is failing.
With the following code: (The two lines of code reside in a general module)

 
MsgBox Forms!frmTMS.OptionLabel8.Caption
MsgBox Forms!Forms(GSwBrdName).Controls("OptionLabel" & GSwBrdOpt).Caption

The first line has the "hard coded" form name and one of the form's control names also "hard coded" so as to confirm the caption. The second line is an attempt to referenced the same caption, but using the global variables to stipulate which form and which control. The controls reference is correct, but the forms reference produces the error:



What should the "Forms(frmName)" syntax be so as to referenced the form?

[orange]

http://access.mvps.org/Access/forms/frm0031.htm

[GraeagleBill]

Sorry orange, the reference makes no mention as to how to substitute the name of the form with the use of a string variable.

[Micron]

This - Forms!Forms( ) is 2 attempts to get a member from the same collection.
To use a variable methinks you'd have to use the latter syntax but as Forms(GSwBrdName)
None of the examples at the link use that syntax, so not sure if any of them really point to the reason why it fails.

[Welshgasman]

Should be form() surely?

Or https://learn.microsoft.com/en-us/of...pi/access.form

[GraeagleBill]

Yes, I has "bang" on the brain being in a general module outside that of the form itself, so it didn't even occur to me that

Forms(GSwBrdName).Controls("OptionLabel" & GSwBrdOpt).Caption

using a simple reference to the forms collection was all that was needed.
Thanks,
Bill

[Edgar]

All you need to do to reference your controls is watch your form variable. There are 4 places to look for your stuff:
1. at the root of your form object
2. in the .Controls property of your form object
3. in the .Form property of your form object
4. in the .Parent property of any item in your .Properties property

The bang just simply replaces the need to write the name of the control with quotes in a parentheses by looking at the object's items' name properties, which is why you should not use a bang if you're programmatically trying to access an object using its name. Here's an example of all this nonsense:

Sub GettingSubformNameInManyWays()
    Dim theForm As Form
    Set theForm = Forms("MainForm")
    
    '----------------------------------
    ' Items in the root of the form object
    Dim rootItem As Variant
    For Each rootItem In theForm
        Debug.Print rootItem.Name
    Next
    Debug.Print "Root appended: ", theForm!SubForm1.Name
    
    '----------------------------------
    ' Items in the "Controls" property of the form object
    Dim controlsItem As Variant
    For Each controlsItem In theForm.Controls
        Debug.Print controlsItem.Name
    Next
    Debug.Print "Controls property bang: ", theForm.Controls!SubForm1.Name
    Debug.Print "Controls property no bang: ", theForm.Controls("SubForm1").Name
    
    '----------------------------------
    ' Items in the "Form" property of the form object
    Dim formItem As Variant
    For Each formItem In theForm.Form
        Debug.Print formItem.Name
    Next
    Debug.Print "Form property bang: ", theForm.Form!SubForm1.Name
    Debug.Print "Form property no bang: ", theForm.Form("SubForm1").Name
    
    '----------------------------------
    ' Items in the "Properties" property of the form object have
    ' a "Parent" property where you can also get references
    ' here's an example of how from the "Caption" property
    ' but could be any other property there, like "PopUp" or whatever
    Debug.Print "From the parent bangs", theForm.Properties!Caption.Parent!SubForm1.Name
    Debug.Print "From the parent no bangs", theForm.Properties("Caption").Parent("SubForm1").Name
End Sub

[orange]

Yes, just saw the updates. I should have read more thoroughly.

Generic:
......
frmName = "MyForm"
cntrlName = "MyControl"


cntrlCaption = Forms(frmName).Controls(cntrlName).Caption or
cntrlCaption = Forms(frmName).Controls("MyControl").Caption