Rich Text Box isn’t scrolling

[Sesame7883]

Hello, I have created a form that has a rich text field with a large amount of text that I need to scroll through. But when I hover my mouse over the box and scroll, nothing happens. Clicking into the field and then scrolling also does nothing. When I scroll, in the lower left corner of the window, a message flashes briefly that says something like "… page, press ctrl-break to stop." Also worth noting that if I click into the field, using page up and page down keys does work to scroll.

Any advice?

[CJ_London]

I presume by 'when I hover my mouse over the box and scroll' you mean you are using the mousewheel. If so you need to use a couple of API's. The below assumes you are using access 2007 or later.


At the top of the form module put

'Scrolling Constants
Private Const WM_VSCROLL = &H115
Private Const SB_LINEUP = 0
Private Const SB_LINEDOWN = 1



Private Declare PtrSafe Function GetFocus Lib "USER32" () As LongPtr
Private Declare PtrSafe Function SendMessage Lib "USER32" Alias "SendMessageA" (ByVal hWnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, lParam As Any) As LongPtr

Function useMouseWheel(wCount As Long)
Dim i  As Long

    For i = 1 To Abs(wCount)
    
        SendMessage GetFocus, WM_VSCROLL, IIf(wCount < 0, SB_LINEUP, SB_LINEDOWN), 0&
    
    Next

End Function

and call it in the form on mouse wheel event - put the name of richtext control where indicated

Private Sub Form_MouseWheel(ByVal Page As Boolean, ByVal Count As Long)
'note to set the active control, it is necessary to click on the control to make it the active control  

     If ActiveControl.Name = "nameOfRichTextControl" Then useMouseWheel (Count)

End Sub

[Sesame7883]

That did it, thank you so much!